How to tell QuickCheck to generate only valid list indices for a parameter?

Question

Say I want to write some unit tests for the (!!) function.

my_prop xs n = ...

I want to restrict n to only valid indexes and I know I could do something like

my_prop xs n = (not.null) (drop n xs) ==> ...

But this makes it so that the vast majority of the generated cases are invalid and get thrown away. Is there a way I can set things up so that QuickCheck generates the xs list first and uses its value to generate only valid cases of n?

Make a new type that contains a list and an `Int` with an appropriate `Arbitrary` instance. — Daniel Wagner, Oct 10 '12 at 20:43

hammar · Accepted Answer · 2012-10-10T21:04:06.653

18

Using forAll, you can specify a generator for n which depends on the earlier arguments, e.g.

my_prop (NonEmpty xs) = forAll (choose (0, length xs - 1)) $ \n -> ...

edited Oct 10 '12 at 21:04

answered Oct 10 '12 at 20:46

hammar

138,522
17
304
385

Neat. If I need two indices in the propety, how can I pass a Gen (Int,Int) to forAll? My current solution is nesting forAll like so: `forAll (indices xs) $ \x -> forAll (indices xs) $ \y -> ...` (using Daniel Fischer's indices definition seen in another answer). – Arild Nov 16 '13 at 12:14

score 10 · Answer 2 · answered Oct 10 '12 at 20:46

You can make a generator that only creates valid indices and write your property like

import Test.QuickCheck
import Test.QuickCheck.Gen
import System.Random

indices :: [a] -> Gen Int
indices xs = MkGen $ \sg _ -> fst $ randomR (0, length xs - 1) sg

my_prop :: [Char] -> Property
my_prop xs = not (null xs) ==> forAll (indices xs) (\i -> xs !! i /= '0')

eliminating the Int argument.

score 5 · Answer 3 · answered Oct 11 '12 at 19:58

As suggested by Daniel Wagner, one possibility is creating my own datatype and giving it an Arbitrary instance.

data ListAndIndex a = ListAndIndex [a] Int deriving (Show)

instance Arbitrary a => Arbitrary (ListAndIndex a) where
   arbitrary = do
     (NonEmpty xs) <- arbitrary
     n  <- elements [0..(length xs - 1)]
     return $ ListAndIndex xs n

NonEmpty is from a custom type in Test.QuickCheck.Modifiers for generating non empty lists.

How to tell QuickCheck to generate only valid list indices for a parameter?

3 Answers3

Linked