Converting base10 to base36 in perl

Question

Possible Duplicate:
What’s the best way to do base36 arithmetic in Perl?

Hello is it possible to convert numbers from a base-10-to-base-36-conversion with perl script?

here's an example :

base 10 - 1234567890123 and outcome
base 36 - FR5HUGNF

What about searching either CPAN or stackoverflow first ? :P — Ouki, Oct 10 '12 at 15:00

score 4 · Answer 1 · answered Oct 10 '12 at 14:59

4

Try using Math::Base36 CPAN library for base conversion.

answered Oct 10 '12 at 14:59

Jean

21,665
24
69
119

I knew we have a gazillion modules and stuff already available for perl on CPAN, but I wouldn't even consider searching on google for a base36 converter :)))) – Tudor Constantin Oct 10 '12 at 15:05
3

@TudorConstantin don't search on google, search on CPAN ;) – hobbs Oct 10 '12 at 15:11

score 3 · Answer 2 · answered Oct 10 '12 at 15:10

Poking around the Math::Base36 source code shows how easy it is to enact the conversion:

sub encode_base36 {
    my ( $number, $padlength ) = @_;
    $padlength ||= 1;

    die 'Invalid base10 number'  if $number    =~ m{\D};
    die 'Invalid padding length' if $padlength =~ m{\D};

    my $result = '';
    while ( $number ) {
        my $remainder = $number % 36;
        $result .= $remainder <= 9 ? $remainder : chr( 55 + $remainder );
        $number = int $number / 36;
    }

    return '0' x ( $padlength - length $result ) . reverse( $result );
}

score 1 · Answer 3 · answered Oct 10 '12 at 16:15

It is quite straightforward to write a subroutine to do this. The code below does no value checking and assumes the numbers to be converted are always non-negative

If your version of Perl isn't sufficiently up-to-date to support the state keyword, then just declare $symbols as a my variable at the head of the program

use strict;
use warnings;

use feature 'state';

print base36(1234567890123);

sub base36 {
  my ($val) = @_;
  state $symbols = join '', '0'..'9', 'A'..'Z';
  my $b36 = '';
  while ($val) {
    $b36 = substr($symbols, $val % 36, 1) . $b36;
    $val = int $val / 36;
  }
  return $b36 || '0';
}

output

FR5HUGNF

Converting base10 to base36 in perl

3 Answers3