Perl passing argument into eval

Question

I'm facing an issue using eval function.

Indeed I have some function name inside a SQL database, my goal is to execute those functions within perl (after retrieve in SQL).

Here is what I'm doing, considering that $RssSource->{$k}{Proceed} contains "&test" as a string retrieved from SQL:

my $str2 = "ABCD";
eval "$RssSource->{$k}{Proceed}";warn if $@;

sub test
{
   my $arg = shift;

   print "fct TEST -> ", $row, "\n";
}

This is working correctly and display:

fct TEST ->

However I would like to be able to pass $str2 as an argument to $RssSource->{$k}{Proceed} but I don't know how, every syntax I tried return an error:

eval "$RssSource->{$k}{Proceed}$str2"
eval "$RssSource->{$k}{Proceed}($str2)"
eval "$RssSource->{$k}{Proceed}"$str2
eval "$RssSource->{$k}{Proceed}"($str2)

May someone tell me how to properly pass an argument to the evaluated function?

Thanks a lot for your help

Regards.

Florent

Did you mean `$arg` instead of `$row`, or the other way around? — paddy, Oct 03 '12 at 21:31
Yes you are right, I have rewritten my code before posting to strictly focus on my issue and didn't change the variable name properly in the test function, sorry — ehretf, Oct 04 '12 at 07:57

ikegami · Accepted Answer · 2012-10-04T01:59:43.220

5

I'm going to assume that $RssSource->{$k}{Proceed} always contain name or &name, otherwise what you are asking doesn't make much sense.

my $func_name = $RssSource->{$k}{Proceed};
$func_name =~ s/&//;
my $func_ref = \&$func_name;    # Works with strict on!
$func_ref->(@args);

If you want to add some error checking, the following will check if the sub can be called:

defined(&$func_ref)

edited Oct 04 '12 at 01:59

answered Oct 03 '12 at 22:21

ikegami

367,544
15
269
518

Isn't line 3 just taking a reference to a sub called literally 'func_name'? – Dondi Michael Stroma Oct 03 '12 at 23:14
@Dondi Michael Stroma, oops, yeah! fixed. – ikegami Oct 04 '12 at 01:53
Thanks a lot Ikegami, looks to be the best way and thank you for your comment concernning error checking ! – ehretf Oct 04 '12 at 08:03

score 3 · Answer 2 · answered Oct 03 '12 at 21:33

If the string you are evaling always is a sub invocation, you can construct the eval string in one of these ways:

$RssSource->{$k}{Proceed} . '($str2)'

(most general), or

$RssSource->{$k}{Proceed} . "(\"$str2\")"

(inelegant)

Here are the problems your solutions ran into:

eval "$RssSource->{$k}{Proceed}$str2" evaluates to eval "&testABCD". This sub doesn't exist.

eval "$RssSource->{$k}{Proceed}($str2)" evaluates to "&test(ABCD)". Bareword not allowed.

eval "$RssSource->{$k}{Proceed}"$str2 A string has to be followed by some sort of operator, not another variable.

eval "$RssSource->{$k}{Proceed}"($str2) You are trying to call a string as a function. This is not supported in Perl.

Thanks for the analyse and your answer Amon, this is really helpfull to understand what I was doing wrong — ehretf, Oct 04 '12 at 08:00

score 2 · Answer 3 · answered Oct 03 '12 at 21:35

2

If you can change the data in your database to contain just a function name, that is, test rather than &test, you can call a function by a symbolic reference, rather than using eval:

$fn="test";
&{$fn}("argument")

answered Oct 03 '12 at 21:35

evil otto

10,348
25
38

Thanks a lot EVil Otto, your are right the eval function is not the way to go – ehretf Oct 04 '12 at 09:16

score 1 · Answer 4 · answered Oct 03 '12 at 23:23

1

You do not need eval if, as you say, your database just contains function names. You can use them as symbolic references (but please remove the &). The modern way to do it would not be using the & to dereference it but to use the arrow operator:

{
    no strict 'refs'; # hopefully you have strict on already...
    $RssSource->{$k}{Proceed}->($str2);
}

answered Oct 03 '12 at 23:23

Dondi Michael Stroma

4,668
18
21

Thanks Dondi, I have to admit that at first read I prefer Ikegami's answer which is compatible with strict ref. May you tell me why you said this is the modern way to achieve this? – ehretf Oct 04 '12 at 09:15
@ehretf ikegami's answer is fine, he does in fact use the arrow operator in the end. I added my own answer because his originally had a mistake in it. Now that it's fixed, I will give it an upvote ;) – Dondi Michael Stroma Oct 04 '12 at 21:21

score 0 · Answer 5 · answered Oct 04 '12 at 02:13

0

Very similar to ikegami's answer, using the can method, which is more my taste. TIMTOWTDI.

my $func_name = $RssSource->{$k}{Proceed};
$func_name =~ s/&//;
my $func_ref = __PACKAGE__->can($func_name)
  or die "No function named $func_name";
$func_ref->(@args);

answered Oct 04 '12 at 02:13

Joel Berger

20,180
5
49
104

Thanks Joel, the can method look interesting ! – ehretf Oct 04 '12 at 09:13

Perl passing argument into eval

5 Answers5