Sed replace pattern with line number

Question

I need to replace the pattern ### with the current line number.

I managed to Print in the next line with both AWK and SED.

sed -n "/###/{p;=;}" file prints to the next line, without the p;, it replaces the whole line.

sed -e "s/###/{=;}/g" file used to make sense in my head, since the =; returns the line number of the matched pattern, but it will return me the the text {=;}

What am i Missing? I know this is a silly question. I couldn't find the answer to this question in the sed manual, it's not quite clear.

If possible, point me what was i missing, and what to make it work. Thank you

[`Since the "=" command only prints to standard output, you cannot print the line number on the same line as the pattern.`](http://www.grymoire.com/Unix/Sed.html#uh-48) — Lev Levitsky, Sep 19 '12 at 14:41
I tested every answer, and the one that worked better was @twalberg 's awk. Thank you, everyone. — ghaschel, Sep 20 '12 at 11:44

score 10 · Accepted Answer · answered Sep 19 '12 at 15:11

10

Simple awk oneliner:

awk '{gsub("###",NR,$0);print}'

answered Sep 19 '12 at 15:11

twalberg

59,951
11
89
84

@Thor Maybe I'm making different assumptions - doesn't that just put the line number at the beginning of the line? I read the OP to mean that "###" might be anywhere in the line, hence the `gsub()`. Although on 2nd reading, it does seem having the number at beginning of line might be what's in mind... – twalberg Sep 19 '12 at 15:49

score 5 · Answer 2 · answered Sep 19 '12 at 15:06

Given the limitations of the = command, I think it's easier to divide the job in two (actually, three) parts. With GNU sed you can do:

$ sed -n '/###/=' test > lineno

and then something like

$ sed -e '/###/R lineno' test | sed '/###/{:r;N;s/###\([^\n]*\n\)\([^\n]*\)/\2\1/;tr;:c;s/\n\n/\n/;tc}'

I'm afraid there's no simple way with sed because, as well as the = command, the r and GNU extension R commands don't read files into the pattern space, but rather directly append the lines to the output, so the contents of the file cannot be modified in any way. Hence piping to another sed command.

If the contents of test are

fooo
bar ### aa
test
zz ### bar

the above will produce

fooo
bar 2 aa
test
zz 4 bar

potong · Answer 3 · 2021-03-10T02:45:31.097

4

This might work for you (GNU sed):

sed = file | sed 'N;:a;s/\(\(.*\)\n.*\)###/\1\2/;ta;s/.*\n//'

An alternative using cat:

cat -n file | sed -E ':a;s/^(\s*(\S*)\t.*)###/\1\2/;ta;s/.*\t//'

edited Mar 10 '21 at 02:45

answered Sep 19 '12 at 21:00

potong

55,640
6
51
83

Can you explain the sed pattern ? – Yohan W. Dunon Aug 02 '21 at 21:13

Thor · Answer 4 · 2014-01-24T23:18:25.113

As noted by Lev Levitsky this isn't possible with one invocation of sed, because the line number is sent directly to standard out.

You could have sed write a sed-script for you, and do the replacement in two passes:

infile

a
b
c
d
e
###
###
###
a
b
###
c
d
e
###

Find the lines that contain the pattern:

sed -n '/###/=' infile

Output:

Pipe that into a sed-script writing a new sed-script:

sed 's:.*:&s/###/&/:'

Output:

6s/###/6/
7s/###/7/
8s/###/8/
11s/###/11/
15s/###/15/

Execute:

sed -n '/###/=' infile | sed 's:.*:&s/^/& \&/:' | sed -f - infile

Output:

a
b
c
d
e
6
7
8
a
b
11
c
d
e
15

Kent · Answer 5 · 2012-09-19T14:59:55.313

1

is this ok ?

kent$  echo "a
b
c
d
e"|awk '/d/{$0=$0" "NR}1'
a
b
c
d 4
e

if match pattern "d", append line number at the end of the line.

edit

oh, you want to replace the pattern not append the line number... take a look the new cmd:

kent$  echo "a
b
c
d
e"|awk '/d/{gsub(/d/,NR)}1'
a
b
c
4
e

and the line could be written like this as well: awk '1+gsub(/d/,NR)' file

edited Sep 19 '12 at 14:59

answered Sep 19 '12 at 14:50

Kent

189,393
32
233
301

The OP needs to substitute the pattern with line number, this is not exactly the answer. – Lev Levitsky Sep 19 '12 at 14:52

score 1 · Answer 6 · answered Nov 28 '18 at 12:21

1

one-liner to modify the FILE in place, replacing LINE with the corresponding line number:

seq 1 `wc -l FILE | awk '{print $1}'` | xargs -IX sed -i 'X s/LINE/X/' FILE

answered Nov 28 '18 at 12:21

simyou

111
1

for osx version of sed I had to modify this as the `-i` param is treated differently https://stackoverflow.com/a/63854797/29924 – Ben Page Sep 11 '20 at 22:00

score 0 · Answer 7 · answered Sep 11 '20 at 21:58

Following on from https://stackoverflow.com/a/53519367/29924

If you try this on osx the version of sed is different and you need to do:

seq 1 `wc -l FILE | awk '{print $1}'` | xargs --verbose -IX sed -i bak "X s/__line__/X/" FILE

see https://markhneedham.com/blog/2011/01/14/sed-sed-1-invalid-command-code-r-on-mac-os-x/

Sed replace pattern with line number

7 Answers7

Linked