In a TComboBox, how can I have the dropdown display X, but the text property gets Y when X is picked?

Question

I need the user to pick a date format (dd/mm/yyyy or dd mmmm yyyy etc...) but displaying these options is just confusing. What I want to be able to do is have the TComboBox items filled with "14/09/2012", "14 September 2012", "Friday 14 September 2012" etc, and when the user picks one of these date formats the combobox gets the text "dd mmmm yyyy" or whatever the date format is (although I still want them to be able to type in something else such as "d/m/yy").

However I haven't found an easy way of doing this - other than a TEdit with a TSpeedButton which opens a form with the selection options in it which is my second choice if there is no way to do this with a TComboBox.

Question: How can I have a TComboBox dropdown display dates, but the text property gets the date format when a date is picked?

score 4 · Answer 1 · answered Sep 14 '12 at 03:47

4

What about ownerdraw the TCombobox?

procedure TForm16.cbLongDateFormatDrawItem(Control: TWinControl; Index: Integer;
  Rect: TRect; State: TOwnerDrawState);
begin
  with Control as TComboBox do
  begin
    if not (odSelected in State) then
      Canvas.Brush.Color:=clWindow
    else
      Canvas.Brush.Color:=clHighlight;
    Canvas.FillRect(Rect);
    Canvas.TextOut(Rect.Left +2 , Rect.Top, FormatDateTime(cbLongDateFormat.Items[Index], Now));
  end;
end;

procedure TForm16.FormCreate(Sender: TObject);
begin
  cbLongDateFormat.Items.Add('ddddd');
  cbLongDateFormat.Items.Add('dddddd');
  cbLongDateFormat.Items.Add('dd/mm/yyyy');
  cbLongDateFormat.Items.Add('d mmmm yyyy');
end;

enter image description here

answered Sep 14 '12 at 03:47

RRUZ

134,889
20
356
483

That's quite cleaver, I hadn't thought of OwnerDraw - doesn't quite give me the behavior that I'm after but will definitely keep it in mind for the future. – Alister Sep 14 '12 at 04:58
That is a better solution (not to mention more dynamic since it displays the current date/time whenever the drop-down is displayed), but there is one thing you have to watch out for - Alister wants the edit field to display the actual format string, not the formatted text. For that, you have to check if the `State` parameter is set to `odComboBoxEdit`. If so, draw `cbLongDateFormat.Items[Index]` as-is. If not, draw the `FormatDateTime()` text instead. – Remy Lebeau Sep 14 '12 at 07:09
Also, by owner-drawing, you do lose the built-in edit field, unfortunately. – Remy Lebeau Sep 14 '12 at 07:18
If `State` is `odComboBoxEdit` then draw `cbLongDateFormat.Text` instead. – Remy Lebeau Sep 14 '12 at 07:18

score 2 · Accepted Answer · answered Sep 14 '12 at 01:29

It is not possible to directly do this via the OnChange event on the ComboBox, as after the OnChange event the text property gets set back to whatever was picked by the user. However I can send a message to the form to make the change.

procedure TfINISettings.cbLongDateFormatChange(Sender: TObject);
begin
  PostMessage(Handle, WM_USER, 0, 0);
end;

and in the form interface declare a procedure

procedure DateFormatComboBoxChange(var msg: TMessage); message WM_USER;

to handle this message, and in the implementation

procedure TfINISettings.DateFormatComboBoxChange(var msg: TMessage);
begin
  if cbLongDateFormat.ItemIndex <> -1 then
    cbLongDateFormat.Text := DateFormats[cbLongDateFormat.ItemIndex];
end;

Where DateFormats is a TStringList that contains my date formats. The FormCreate method looks like this

procedure TfINISettings.FormCreate(Sender: TObject);
var
  d: String;
begin
  DateFormats := TStringList.Create;
  DateFormats.Add('ddddd');
  DateFormats.Add('dddddd');
  DateFormats.Add('d mmmm yyyy');
  for d in DateFormats do
    cbLongDateFormat.Items.Add(FormatDateTime(d, now));
end;

Suggestions on improvements welcome.

RRUZ's solution almost does what I want but not quite - this is the solution that I ended up using although I don't like answering my own question. — Alister, Sep 17 '12 at 01:33

score 1 · Answer 3 · answered Sep 14 '12 at 00:43

1

Store your date/time format strings in a separate TStringList, then in the TComboBox.OnChange event, you can use the TComboBox.ItemIndex property to know which drop-down list item was selected so you can assign the corresponding TStringList item to the TComboBox.Text property.

answered Sep 14 '12 at 00:43

Remy Lebeau

555,201
31
458
770

Yes, this was my first idea, but it doesn't work: if eLongDateFormat.ItemIndex <> -1 then eLongDateFormat.Text := DateFormats[eLongDateFormat.ItemIndex]; – Alister Sep 14 '12 at 00:51
@Alister: Save the `ComboBox` item index in the `StringList.Object` list, and you can then use it as a lookup to determine the proper date format to display. – Ken White Sep 14 '12 at 01:42
@KenWhite: You don't need to do that if `eLongDateFormat.Items` and `DateFormats` have the same number of items. – Remy Lebeau Sep 14 '12 at 02:04
1

Remy: You do if you don't make sure they're in the same order in both lists; if either is sorted, the linkage is broken. Saving the index prevents that from happening. @Alister: I was responding to your first comment here to Remy about not being able to use `ItemIndex`, not about displaying via OnChange (which is why I posted a comment instead of an answer - I think your approach is wrong, but you didn't ask about better alternatives). – Ken White Sep 14 '12 at 02:08

In a TComboBox, how can I have the dropdown display X, but the text property gets Y when X is picked?

3 Answers3