How to ping multiple servers and return IP address and Hostnames using batch script?

Question

So I have to use batch only for this. Basically, the server HOSTNAMES are all listed in a txt file. I used the following code to ping all the servers and display their results in a txtfile.

For /f %%i in (testservers.txt) do ping -n 1 %%i >>pingtest.txt

The above pinged all the servers. Now, I want to output the IP addresses and the HOST Names in a separate file. How can I do this? I know that I can run a for loop searching for words like "TTL" and then look for the 3rd token (for the IP) and words like "PINGING" for the second token(HOSTNAME). But I am having errors and cant display it properly. The reason why I want to output IPs and Hostnames in a different file is to make a list of the DOWN and UP servers.

Help will be appreciated. :)

EDIT: Just so it isn't confusing, wanted to let you guys know there are 3 different files, testservers.txt has the HOSTNAMES in it, pingtest.txt has ping results, and result.txt will have the IPs along with Hostnames with their current status as DOWN or UP.

http://stackoverflow.com/questions/3050898/how-to-check-if-ping-responded-or-not-in-a-batch-file should help you — SeanC, Sep 13 '12 at 16:13

Eitan T · Accepted Answer · 2016-02-16T08:59:15.957

20

Well, it's unfortunate that you didn't post your own code too, so that it could be corrected.
Anyway, here's my own solution to this:

@echo off
setlocal enabledelayedexpansion

set OUTPUT_FILE=result.txt
>nul copy nul %OUTPUT_FILE%
for /f %%i in (testservers.txt) do (
    set SERVER_ADDRESS=ADDRESS N/A
    for /f "tokens=1,2,3" %%x in ('ping -n 1 %%i ^&^& echo SERVER_IS_UP') do (
        if %%x==Pinging set SERVER_ADDRESS=%%y
        if %%x==Reply set SERVER_ADDRESS=%%z
        if %%x==SERVER_IS_UP (set SERVER_STATE=UP) else (set SERVER_STATE=DOWN)
    )
    echo %%i [!SERVER_ADDRESS::=!] is !SERVER_STATE! >>%OUTPUT_FILE%
)

The outer loop iterates through the hosts and the inner loop parses the ping output. The first two if statements handle the two possible cases of IP address resolution:

The host name is the host IP address.
The host IP address can be resolved from its name.

If the host IP address cannot be resolved, the address is set to "ADDRESS N/A".

Hope this helps.

edited Feb 16 '16 at 08:59

answered Sep 13 '12 at 17:34

Eitan T

32,660
14
72
109

+1 - I like it. The code is language dependent. It will have to change for languages other than English. – dbenham Sep 13 '12 at 18:38
Do you think there's a French/German/Dutch version of `ping`? – Eitan T Sep 13 '12 at 21:48
2

Absolutely! [This thread](https://www.itefix.no/i2/content/problem-checkwinpingexe) has sample output for German, Portuguese, French?, and Polish? – dbenham Sep 13 '12 at 22:12
1

Amazing EitanT. Thank you. Sorry I couldn't have posted my code as it had some stuff that belongs to the company. Can't go around posting it. But nevertheless, what I did was vaguely similar except I had 2 separate for loops to extract IP and HOSTNAME but I was unable to do the "UP" and "DOWN" check since it was 2 different for loops. – Gutsygibbon Sep 14 '12 at 14:04
@EitanT , does it handle `Reply from 192.168.2.1: Destination host unreachable.` ? – Ofiris Feb 17 '13 at 07:51
So is there something special i have to do with the above script. I created the script and ran it according to the above directestions and it shot my Memory up to the max, 16GB and i have to restart my server. – Anthony Fornito Mar 14 '14 at 15:51
@user2566483 I'm not sure this is related, this script doesn't use up a lot of memory on it's own. – Eitan T Mar 18 '14 at 10:57
It handles situations when the destination is unreachable but don't extract IPs when the request is timed out. For example, it shows DOWN for msn.com, but when I ping it manually I get `pinging msn.com [23.101.196.141] Request timed out` so IP is detectable and, moreover, the host is **perfectly reachable** from browser. – Suncatcher Aug 18 '16 at 15:37
@Suncatcher I'm not sure I understand where the problem is. The script shows DOWN if there's no reply from the destination. – Eitan T Aug 24 '16 at 05:13

score 4 · Answer 2 · answered Sep 13 '12 at 16:20

4

Parsing pingtest.txt for each HOST name and result with batch is difficult because the name and result are on different lines.

It is much easier to test the result (the returned error code) of each PING command directly instead of redirecting to a file. It is also more efficient to enclose the entire construct in parens and redirect the final output just once.

>result.txt (
  for /f %%i in (testservers.txt) do ping -n 1 %%i >nul && echo %%i UP||echo %%i DOWN
)

answered Sep 13 '12 at 16:20

dbenham

127,446
28
251
390

Neat, but this doesn't extract the IP address, which requires parsing the ping instead of redirecting it to `nul`. +1 anyway. – Eitan T Sep 13 '12 at 17:36

score 2 · Answer 3 · answered Jan 12 '15 at 23:57

I worked on the code given earlier by Eitan-T and reworked to output to CSV file. Found the results in earlier code weren't always giving correct values as well so i've improved it.

testservers.txt

SOMESERVER
DUDSERVER

results.csv

HOSTNAME    LONGNAME                    IPADDRESS   STATE 
SOMESERVER  SOMESERVER.DOMAIN.SUF       10.1.1.1    UP 
DUDSERVER   UNRESOLVED                  UNRESOLVED  DOWN

pingtest.bat

 @echo off
    setlocal enabledelayedexpansion
    set OUTPUT_FILE=result.csv

    >nul copy nul %OUTPUT_FILE%
    echo HOSTNAME,LONGNAME,IPADDRESS,STATE >%OUTPUT_FILE%
    for /f %%i in (testservers.txt) do (
        set SERVER_ADDRESS_I=UNRESOLVED
        set SERVER_ADDRESS_L=UNRESOLVED
        for /f "tokens=1,2,3" %%x in ('ping -n 1 %%i ^&^& echo SERVER_IS_UP') do (
        if %%x==Pinging set SERVER_ADDRESS_L=%%y
        if %%x==Pinging set SERVER_ADDRESS_I=%%z
            if %%x==SERVER_IS_UP (set SERVER_STATE=UP) else (set SERVER_STATE=DOWN)
        )
        echo %%i [!SERVER_ADDRESS_L::=!] !SERVER_ADDRESS_I::=! is !SERVER_STATE!
        echo %%i,!SERVER_ADDRESS_L::=!,!SERVER_ADDRESS_I::=!,!SERVER_STATE! >>%OUTPUT_FILE%
    )

it's showing IP address even when server is down and easily available in excel. best solution. — IT hero, Nov 12 '22 at 03:59

peet · Answer 4 · 2013-03-14T21:01:48.123

the problem with ping is if the host is not alive often your local machine will return an answer that the pinged host is not available, thus the errorcode of ping will be 0 and your code will run in error because not recognizing the down state.

better do it this way

ping -n 4 %1 | findstr TTL
if %errorlevel%==0 (goto :eof) else (goto :error)

this way you look for a typical string ttl which is always in the well done ping result and check error on this findstr instead of irritating ping

overall this looks like this:

@echo off
SetLocal


set log=path/to/logfile.txt
set check=path/to/checkfile.txt

:start
echo. some echo date >>%log%

:check
for /f %%r in (%check%) do (call :ping %%r)
goto :eof

:ping
ping -n 4 %1 | findstr TTL
if %errorlevel%==0 (goto :eof) else (goto :error)

:error
echo. some errormessage to >>%log%
echo. some blat to mail?

:eof
echo. some good message to >>%log%

score 0 · Answer 5 · edited Feb 27 '14 at 22:55

0

Try this

$servers = Get-Content test.txt

$reg=""

foreach ($server in $servers) 

{

$reg=$reg+$server+"`t"+([System.Net.Dns]::GetHostAddresses($server) | foreach {echo $_.IPAddressToString})+"`n"

 }
$reg >reg.csv

edited Feb 27 '14 at 22:55

Szymon

42,577
16
96
114

answered Feb 27 '14 at 22:37

Naveen Sharma

1
2

Your script is in bash. The question is about *batch*. – Eitan T Feb 16 '16 at 08:58
@EitanT, It's not Bash, it's Powershell. – Suncatcher Aug 18 '16 at 16:09
@Suncatcher I stand corrected. And still, the question's requirement is batch only... – Eitan T Aug 20 '16 at 03:38

score 0 · Answer 6 · answered Apr 01 '16 at 18:16

@echo off

set workdir={your working dir. for example - C:\work } set iplist=%workdir%\IP-list.txt

setlocal enabledelayedexpansion
set OUTPUT_FILE=%workdir%\result.csv

>nul copy nul %OUTPUT_FILE%
echo HOSTNAME,LONGNAME,IPADDRESS,STATE >%OUTPUT_FILE%
for /f %%i in (%iplist%) do (
    set SERVER_ADDRESS_I=UNRESOLVED
    set SERVER_ADDRESS_L=UNRESOLVED
    for /f "tokens=1,2,3" %%x in ('ping -a -n 1 %%i ^&^& echo SERVER_IS_UP') do (
    if %%x==Pinging set SERVER_ADDRESS_L=%%y
    if %%x==Pinging set SERVER_ADDRESS_I=%%z
        if %%x==SERVER_IS_UP (set SERVER_STATE=UP) else (set SERVER_STATE=DOWN)
    )
    echo %%i [!SERVER_ADDRESS_L::=!] !SERVER_ADDRESS_I::=! is !SERVER_STATE!
    echo %%i,!SERVER_ADDRESS_L::=!,!SERVER_ADDRESS_I::=!,!SERVER_STATE! >>%OUTPUT_FILE%
)

Please explain how your answer solves the problem, it will help everyone understand your solution with more clarity and for future reference. — Aziz, Apr 01 '16 at 18:36

score 0 · Answer 7 · edited May 23 '17 at 12:10

This worked great I just add the -a option to ping to resolve the hostname. Thanks https://stackoverflow.com/users/4447323/wombat

@echo off setlocal enabledelayedexpansion set OUTPUT_FILE=result.csv

>nul copy nul %OUTPUT_FILE%
echo HOSTNAME,LONGNAME,IPADDRESS,STATE >%OUTPUT_FILE%
for /f %%i in (testservers.txt) do (
    set SERVER_ADDRESS_I=UNRESOLVED
    set SERVER_ADDRESS_L=UNRESOLVED
    for /f "tokens=1,2,3" %%x in ('ping -n 1 -a %%i ^&^& echo SERVER_IS_UP') do (
    if %%x==Pinging set SERVER_ADDRESS_L=%%y
    if %%x==Pinging set SERVER_ADDRESS_I=%%z
        if %%x==SERVER_IS_UP (set SERVER_STATE=UP) else (set SERVER_STATE=DOWN)
    )
    echo %%i [!SERVER_ADDRESS_L::=!] !SERVER_ADDRESS_I::=! is !SERVER_STATE!
    echo %%i,!SERVER_ADDRESS_L::=!,!SERVER_ADDRESS_I::=!,!SERVER_STATE! >>%OUTPUT_FILE%
)

score 0 · Answer 8 · edited Apr 19 '18 at 21:32

This works for spanish operation system.

Script accepts two parameters:

a file with the list of IP or domains
output file

script.bat listofurls.txt output.txt

@echo off
setlocal enabledelayedexpansion
set OUTPUT_FILE=%2
>nul copy nul %OUTPUT_FILE%
for /f %%i in (%1) do (
    set SERVER_ADDRESS=No se pudo resolver el host
    for /f "tokens=1,2,3,4,5" %%v in ('ping -a -n 1 %%i ^&^& echo SERVER_IS_UP') 
    do (
        if %%v==Haciendo set SERVER_ADDRESS=%%z
        if %%v==Respuesta set SERVER_ADDRESS=%%x
        if %%v==SERVER_IS_UP (set SERVER_STATE=UP) else (set SERVER_STATE=DOWN)
    )
    echo %%i [!SERVER_ADDRESS::=!] is !SERVER_STATE! >>%OUTPUT_FILE%
    echo %%i [!SERVER_ADDRESS::=!] is !SERVER_STATE!
)

How to ping multiple servers and return IP address and Hostnames using batch script?

8 Answers8

Linked