How to get programatically the file path from a directory parameter in abap?

Question

The transaction AL11 returns a mapping of "directory parameters" to file paths on the application server AFAIK. The trouble with transaction AL11 is that its program only calls c modules, there's almost no trace of select statements or function calls to analize there.

I want the ability to do this dynamically, in my code, like for instance a function module that took "DATA_DIR" as input and "E:\usr\sap\IDS\DVEBMGS00\data" as output.

This thread is about a similar topic, but it doesn't help.

Some other guy has the same problem, and he explains it quite well here.

score 4 · Accepted Answer · answered Aug 17 '12 at 14:27

I strongly suspect that the only way to get these values is through the kernel directly. some of them can vary depending on the application server, so you probably won't be able to find them in the database. You could try this:

TYPE-POOLS abap.

TYPES: BEGIN OF t_directory,
         log_name TYPE dirprofilenames,
         phys_path TYPE dirname_al11,
       END OF t_directory.

DATA: lt_int_list    TYPE TABLE OF abaplist,
      lt_string_list TYPE list_string_table,
      lt_directories TYPE TABLE OF t_directory,
      ls_directory   TYPE t_directory.

FIELD-SYMBOLS: <l_line> TYPE string.

START-OF-SELECTION-OR-FORM-OR-METHOD-OR-WHATEVER.
* get the output of the program as string table
  SUBMIT rswatch0 EXPORTING LIST TO MEMORY AND RETURN.
  CALL FUNCTION 'LIST_FROM_MEMORY'
    TABLES
      listobject = lt_int_list.
  CALL FUNCTION 'LIST_TO_ASCI'
    EXPORTING
      with_line_break   = abap_true
    IMPORTING
      list_string_ascii = lt_string_list
    TABLES
      listobject        = lt_int_list.

* remove the separators and the two header lines
  DELETE lt_string_list WHERE table_line CO '-'.
  DELETE lt_string_list INDEX 1.
  DELETE lt_string_list INDEX 1.

* parse the individual lines
  LOOP AT lt_string_list ASSIGNING <l_line>.
*   If you're on a newer system, you can do this in a more elegant way using regular expressions
    CONDENSE <l_line>.
    SHIFT <l_line> LEFT DELETING LEADING '|'.
    SHIFT <l_line> RIGHT DELETING TRAILING '|'.
    SPLIT <l_line>+1 AT '|' INTO ls_directory-log_name ls_directory-phys_path.
    APPEND ls_directory TO lt_directories.
  ENDLOOP.

Called 'LIST_FROM_MEMORY' and got nothing. I don't know what that could mean, but i'll keep looking for a solution. Thx. — vlad-ardelean, Aug 17 '12 at 15:04
LIST_FROM_MEMORY fetches the list that was stored by SUBMIT ... EXPORTING LIST TO MEMORY. If you don't SUBMIT anything before calling it, you won't get anything. RSWATCH0 is the program behind AL11. — vwegert, Aug 17 '12 at 15:37
Truly amazing piece of code, thx a lot. I'm pretty new to abap, and this was one of the coolest things i've seen written in it so far :D — vlad-ardelean, Aug 17 '12 at 15:56

score 1 · Answer 2 · edited Feb 20 '13 at 13:15

1

Try the following

data : dirname type  DIRNAME_AL11.
CALL 'C_SAPGPARAM' ID 'NAME'  FIELD 'DIR_DATA'
                   ID 'VALUE' FIELD dirname.

Alternatively if you wanted to use your own parameters(AL11->configure) then read these out of table user_dir.

edited Feb 20 '13 at 13:15

Rikesh

26,156
14
79
87

answered Feb 20 '13 at 12:57

Michael Bruhn

11
1

though i wouldn't want to call a C function directly, this seems a lot more elegant than parsing program output – vlad-ardelean Feb 23 '13 at 07:28

How to get programatically the file path from a directory parameter in abap?

2 Answers2

Linked