Erlang: how can I reference an anonymous function from within the body?

Question

In Erlang is there a way reference the currently executing function)?

That would be useful to spawn an infinite loop:

spawn(fun() -> do_something, this_fun() end)

In JavaScript arguments.callee does just that, see the specification on MDC.

Edit to answer a 'why would you do that': mostly curiosity; it is also useful to define a timer when prorotyping:

Self = self(),
spawn(fun() -> Self ! wake_up, receive after 1000 -> nil end, this_fun() end),
%% ...

This has also been answered in this question: http://stackoverflow.com/questions/867418/how-do-you-write-a-fun-thats-recursive-in-erlang/867525#867525 — Adam Lindberg, Oct 09 '09 at 12:42
"Funs with Names": http://www.erlang.org/eeps/eep-0037.html, which was merged into Erlang in late 2012. — Roger Lipscombe, Dec 19 '13 at 21:38

legoscia · Accepted Answer · 2014-05-20T12:16:20.527

In Erlang/OTP 17.0-rc1, you can use a named fun for that:

1> Self = self(),
1> Fun = fun ThisFun() ->
             Self ! wake_up,
             receive after 1000 -> nil end,
             ThisFun()
         end.
#Fun<erl_eval.44.71889879>
2> spawn(Fun).
<0.35.0>
3> flush().
Shell got wake_up
Shell got wake_up
Shell got wake_up
ok

In earlier versions, there is no way to do exactly that. You could pass the function itself as an argument:

Self = self(),
Fun = fun(ThisFun) ->
          Self ! wake_up,
          receive after 1000 -> nil end,
          ThisFun(ThisFun)
      end
spawn(fun() -> Fun(Fun) end),
%% ...

score 7 · Answer 2 · answered Jul 24 '09 at 21:03

If you feel like twisting things a little bit:

Y = fun(M,B) -> G = fun(F) -> M(fun() -> (F(F))() end, B) end, G(G) end.
spawn(Y(fun(F, ParentPid) -> fun() -> ParentPid ! wake_up, receive after 1000 -> ok end, F() end end, self())).

Flush the messages couple times to see the result:

flush().

Of course, Y is more useful if you put it in some sort of library. Also you can find this post on Y Combinators: http://bc.tech.coop/blog/070611.html quite interesting

score 3 · Answer 3 · answered Oct 08 '09 at 13:52

The Erlang language does not expose any way for anonymous functions to refer to them self, but there is a rumour that Core Erlang (an intermediate but official representation in the compiler phases) does have such a feature.

I don't know why I am forwarding this, but you know, if you happen to be generating Core Erlang in a DSL or similar it is something that is within reach.

Erlang: how can I reference an anonymous function from within the body?

3 Answers3

Linked