Is there a better way to express the absolute error function in point-free notation?

Question

In pointful notation:

absoluteError x y = abs (x-y)

An unclear example in pointfree notation:

absoluteError' = curry (abs . uncurry (-))

If it's clear in pointy notation, then what's wrong with it? This looks like the sort of example where any point-free version is going to have to be read by mentally converting back anyway... — Ben, Jun 13 '12 at 00:49

Will Ness · Accepted Answer · 2012-06-13T08:12:21.407

33

Here's how you could derive it yourself, in small steps:

absoluteError x y = abs (x-y) = abs ((-) x y) = abs ( ((-) x) y) 
                  = (abs . (-) x) y = ( (abs .) ((-) x) ) y = 
                  = ( (abs .) . (-) ) x y

so, by eta-reduction, if f x y = g x y we conclude f = g.

Further, using _B = (.) for a moment,

(abs .) . (-) = _B (abs .) (-) = _B (_B abs) (-) = (_B . _B) abs (-)
              = ((.) . (.)) abs (-)

edited Jun 13 '12 at 08:12

answered Jun 13 '12 at 06:20

Will Ness

70,110
9
98
181

1

Plus one for the previous help and perfect answer – developer_hatch Nov 02 '17 at 12:43

score 26 · Answer 2 · edited Aug 01 '13 at 06:14

26

Here's a handful of ways.

the old-fashioned: absoluteError = (abs .) . (-)
use the so-called "boobs operator", or "owl operator" absoluteError = ((.) . (.)) abs (-)
name the boobs operator something more politically correct (and what the heck, generalize it at the same time)
```
(.:) = fmap fmap fmap
absoluteError = abs .: (-)
```

using semantic editor combinators:

result :: (o1 -> o2) -> (i -> o1) -> (i -> o2)
result = (.)

absoluteError = (result . result) abs (-)

Of course, these are all the same trick, just with different names. Enjoy!

edited Aug 01 '13 at 06:14

Davorak

7,362
1
38
48

answered Jun 13 '12 at 00:49

Daniel Wagner

145,880
9
220
380

1

Why isn't `.:` defined anywhere standard, anyway? Or is it? – leftaroundabout Jun 13 '12 at 14:44
3

@leftroundabout It's defined in several hackage packages, but it's such a tiny definition that most people don't feel the extra dependency is worth the effort, I think. – Daniel Wagner Jun 13 '12 at 16:12
@DanielWagner: Is it? I couldn't find it anywhere. – Bergi Oct 15 '14 at 12:55

Is there a better way to express the absolute error function in point-free notation?

2 Answers2

Linked