F# Explicit Interface Method for Two Interfaces

Question

What is the correct way to handle this situation. I have one method in my F# class DogTree that should fulfill the requirement of implementing a Bark() method for both interfaces.

type ITree =
    interface
        abstract Bark : unit -> unit
        abstract Grow : unit -> unit
    end

type IDog =
    interface
        abstract Bark : unit -> unit
        abstract ChaseCar : unit -> unit
    end

type TreeDog = 
   // so the "and" syntax below doesn't work - what is the correct way to handle?
   interface IDog and ITree with
      member this.Bark() = printfn "Bark"

Jordão · Accepted Answer · 2012-05-21T03:20:21.467

You can delegate to a common implementation:

type TreeDog = 
  interface IDog with
    member this.Bark() = printfn "Bark" 
  interface ITree with
    member this.Bark() = (this :> IDog).Bark()

Or, more appropriately:

type TreeDog = 
  member this.Bark() = printfn "Bark"
  interface IDog with
    member this.Bark() = this.Bark() 
  interface ITree with
    member this.Bark() = this.Bark()

(Note that this defines an extra method in the class named Bark, that is used as the implementation for both interfaces.)

If you declare a primary constructor in your class, you can use this instead:

type TreeDog() = // primary constructor
  let bark() = printfn "Bark" // this member is private
  interface IDog with
    member this.Bark() = bark()
  interface ITree with
    member this.Bark() = bark()

score 3 · Answer 2 · edited May 21 '12 at 15:55

3

This is reasonably elegant

type TreeDog() = 
  let bark() = printfn "Bark" 
  interface IDog with
    member this.Bark() = bark()
  interface ITree with
    member this.Bark() = bark()

edited May 21 '12 at 15:55

Joel Mueller

28,324
9
63
88

answered May 21 '12 at 03:03

John Palmer

25,356
3
48
67

F# Explicit Interface Method for Two Interfaces

2 Answers2