Flex - How to get the parameters passed to a RemoteObject call when a FaultEvent is triggered?

Question

I call a RemoteObject method inside a loop. This method receive a row id as parameter that deletes the row in a database. Inside a loop, lots of calls could be made at once. Some of the calls could fire a FaultEvent. How do I detect the row id that fired the FaultEvent?

The remoteobject:

<mx:RemoteObject id="myTableFactory" destination="myTableFactoryFactory"/>

The loop:

myTableFactory.addEventListener(FaultEvent.FAULT, faultFunction);
for each (var myTableRow:myTable in rowsToBeExcludedArray)
{
  myTableFactory.removeMyTableRow(myTableRow.id);
}

private function faultFunction(e:FaultEvent):void
{
  // The main question. How to get myTableRow.id that fired the FaultEvent
}

Thanks.

Carlos Lima.

score 1 · Answer 1 · answered May 11 '12 at 11:51

You should definitely read up on AsyncToken.

Every remote procedure call on a RemoteObject will return one:

var token:AsyncToken = myTableFactory.removeMyTableRow(myTableRow.id);

There are now two things you can do with this token.

Add a Responder

You can add a Responder to each call, which gives you the possibility to have a unique handler for each call:

token.addResponder(new Responder(handleResult, handleFault));

Be sure to remove your global result and fault handlers before trying this. Also I've used the default Responder class here, but any class implementing IResponder will do.

Piggyback your id

You can add new properties to the token since it's a dynamic class. For instance the id may come in handy here:

token.removedId = myTableRow.id;

Or maybe even the entire class:

token.removedRow = myTableRow;

Now you can find these values in the event handlers:

private function handleResult(event:ResultEvent):void {
    trace(event.token.removedId);
}

The same principle applies to FaultEvent

+1 from me for the suggestion to PiggyBack the ID. That sounds like what is needed; and it's a creative use of the ASyncToken I never thought of before. — JeffryHouser, May 11 '12 at 13:14

score 0 · Answer 2 · answered Feb 25 '13 at 11:34

If you don't like the idea of piggy backing your AsyncToken (and I don't particularly as is sometime impractical) you can retrieve the details of the original request quite easily.

I use this technique when encountering DuplicateSessionDetected errors with BlazeDS, to null the client id and re-issue the originating request.

private function handleFault(event:FaultEvent):void
{
    const remoteObject:RemoteObject = (event.target as RemoteObject);
    const message:RemotingMessage = (event.token.message as RemotingMessage);

    message.clientId = null;
    remoteObject.getOperation(message.operation)
        .send.apply(null, message.body);
}

Hope that helps!

Flex - How to get the parameters passed to a RemoteObject call when a FaultEvent is triggered?

2 Answers2