Adding value to array if condition is fulfilled

Question

I am building an array of hashes of arrays

my @array = (
    {label => 'first hash'},
    {label => 'second hash',
     innerarray => [
        {label => 'first inner hash'},
        {label => 'second inner hash'},
      ]
    },
);

Is there a way to only add the second inner hash only if a condition is fullfilled? Something like this:

my @array = (
    {label => 'first hash'},
    {label => 'second hash',
     innerarray => [
        {label => 'first inner hash'},
        {label => 'second inner hash'} if 1==1,
      ]
    },
);

I tried to rewrite my code using push:

my @innerarray = ();
push @innerarray, {label => 'first inner hash'};
push @innerarray, {label => 'second inner hash'} if 1==1;

my @array = (
    {label => 'first hash'},
    {label => 'second hash',
     innerarray => \@innerarray
    },
);

But it becomes very illegible, as I have to predefine all inner array before using them, which in some cases is several 100 lines of code above the usage.

Is there any way to add the if-condition directly where I insert the array-element?

score 9 · Accepted Answer · edited May 02 '12 at 15:53

9

Use the conditional operator, it is usable as expression.

my @array = (
    {label => 'first hash'},
    {
        label      => 'second hash',
        innerarray => [
            {label => 'first inner hash'},
            (1 == 1)
                ? {label => 'second inner hash'}
                : (),
        ]
    },
);

edited May 02 '12 at 15:53

ikegami

367,544
15
269
518

answered May 02 '12 at 14:09

daxim

39,270
4
65
132

1

"Ternary operator" isn't its name, it's just a description of how many operands it takes. The conditional operator is not Perl's only ternary operator. (e.g. `dbmopen`) Fixed. – ikegami May 02 '12 at 15:54

dgw · Answer 2 · 2012-05-02T14:11:21.467

You are storing an array reference in your innerarray (example 1) but in your rewrite you try to store the array.
Try this instead:

my @innerarray = () ;
push @innerarray, {label => 'first inner hash'};
push @innerarray, {label => 'second inner hash'} if 1==1; # Not a real condition ...

my @array = (
    {label => 'first hash'},
    {label => 'second hash',
     innerarray => \@innerarray
    },
) ;

And you were also missing a ; twice.

And for your question on inlining some content ...

my @array = (
    {label => 'first hash'},
    {label => 'second hash',
     innerarray => [
        {label => 'first inner hash'},
        ( $condition == 1 ? {label => 'second inner hash'} : () ) ,
      ]
    },
) ;

score 3 · Answer 3 · answered May 02 '12 at 14:10

You can do:

#!/usr/bin/env perl

use strict; use warnings;

my @array = (
    {label => 'first hash'},
    {label => 'second hash',
     innerarray => [
        {label => 'first inner hash'},
        1 == 0 ? {label => 'second inner hash'} : (),
      ]
    },
);

use YAML;
print Dump \@array;

Output:

---
- label: first hash
- innerarray:
    - label: first inner hash
  label: second hash

But, why?

You can also do:

    ({label => 'second inner hash'}) x (1 == 0),

but, again, why?

Specifically, embedding this in the initialization of the data structure visually hides what's happening from the reader of the code. If the conditions are even slightly complicated, you're bound to introduce hard to trace errors.

score 3 · Answer 4 · answered May 02 '12 at 15:53

In addition to the conditional operator ( and sometimes in combination with it), map is often useful in similar circumstances.

my @labels = (
    'first inner hash',
    'second inner hash',
);

my @array = (
    {label => 'first hash'},
    {
        label      => 'second hash',
        innerarray => [
            ( map { { label => $_ } } @labels ),
        ]
    },
);

Adding value to array if condition is fulfilled

4 Answers4