ASP Classic - Parse XML InnerXML

Question

I like to be able to parsing the value like asp.net, unfortunately the asp classic also return the tag like the <div>everything within it</div> tag.

I am trying to parse the path "/root/div" and return everything within it, not including the "<div></div>", the result should be "<p>abc <span>other span</span></p>"

<%
    Set CurrentXML=Server.CreateObject("Microsoft.XMLDOM")
    CurrentXML.LoadXml("<root><div><p>abc <span>other span</span></p></div></root>")'Load string into CurrentXML

    Response.Write("<BR>"&Server.HTMLEncode(CurrentXML.SelectSingleNode("/root/div").XML)) 'I want to return  without the div, the correct result should be <p>abc <span>other span</span></p>
 %>

score 2 · Accepted Answer · answered Apr 29 '12 at 20:55

Try this:

<%
Option Explicit

    Dim xml: Set xml = Server.CreateObject("MSXML2.DOMDocument.3.0") 
    xml.LoadXml("<root><div>Text Start<p>abc <span>other span</span></p></div></root>")

    Dim sResult: sResult = ""

    Dim node
    For Each node in xml.selectSingleNode("/root/div").childNodes
        sResult = sResult & node.xml
    Next

    Response.Write Server.HTMLEncode(sResult) 

%>

Unfortunately the MSXML DOM elements do not have an innerXml property. Hence you need to the loop as exemplified about to concatenate the xml of each child node to genereate the inner XML of an element.

score 2 · Answer 2 · answered Apr 29 '12 at 20:57

2

This should get you what you're looking for:

Response.Write("BR>"&Server.HTMLEncode(CurrentXML.SelectSingleNode("/root/div").childNodes.item(0).XML))

I'm not sure about your exact case, but you might want to make sure that you have child nodes before assuming that, you can do it with:

CurrentXML.SelectSingleNode("/root/div").hasChildNodes ' Should be "True"

Good luck!

answered Apr 29 '12 at 20:57

Adi

707
6
12

This approach only works if the HTML fragment contained in the "div" only contains one xml child node. See my answer where I've injected a case where there is also a loose text node in there. – AnthonyWJones Apr 29 '12 at 21:03
Hi, thanks for noticing. You're right, I answered regarding the specific XML given as an example, this should be taken in consideration. – Adi Apr 29 '12 at 21:10
thanks guys, Adi simple solution solved my problem. Thank you. – James Smith Apr 29 '12 at 21:30

ASP Classic - Parse XML InnerXML

2 Answers2