Batch Script Copying Files

Question

I'm having trouble trying to create a batch script to copy a file from source A to source B, but need to copy the newest file by date with a file size that is larger than 1KB. It also need to copy a file from source A and overwrites a file that resides in source B.

I use the follow script below as example how i'm setting it up.

xcopy E:\sourceA\testA_* /DA C:\sourceB\TestB.txt /Y

I don't know how to add the command to grab a file that is larger than 1KB. Any help on this would be greatly appreciated. Sorry scripting is not my thing and new at it.

Don't use .bat files. Try Perl, Windows script host, or Powershell. Or write a C# or VB.Net program. But .bat files are just too primitive to do much of anything besides what you've already got. IMHO... — paulsm4, Apr 24 '12 at 23:21
There's no way to check the file size using XCopy. You can probably do it using a PowerShell script, but XCopy has no functionality to consider file sizes. — Ken White, Apr 24 '12 at 23:23
Hmm okay...guess i'll look into powershell script. New to this stuff. Thanks for the advice. Greatly Appreciated — JayC1980, Apr 24 '12 at 23:35

score 1 · Answer 1 · answered Apr 25 '12 at 02:53

1

I'm not sure I fully understand your requirements, but I think this is what you asked for

@echo off
pushd "E:\sourceA"
for /f "eol=: delims=" %%F in ('dir /a-d /b /o-d "testA_*"') do (
  if %%~zF geq 1024 (
      copy /y "%%F" "C:\sourceB\TestB.txt"
      goto :break
    )
)
:break

If you only want to copy a file if it has the Archive attribute, and only if it is newer than the existing TestB.txt, then

@echo off
pushd "E:\sourceA"
for /f "eol=: delims=" %%F in ('dir /aa-d /b /o-d "testA_*"') do (
  if %%~zF geq 1024 (
      echo f|xcopy /dy "%%F" "C:\sourceB\TestB.txt"
      goto :break
    )
)
:break

answered Apr 25 '12 at 02:53

dbenham

127,446
28
251
390

dbbenham thanks for your help but what im asking is for copyng the newest files from source_A with a size greater than 2kb in filesize, going into source_B overwriting text_B – JayC1980 Apr 26 '12 at 23:09
Greater than 1kb as in your question, or 2kb as in your comment? Also, only one file can be named text_B in your destination folder; so I don't understand the concept of copying multiple files to overwrite a single file. The answer I posted copies the newest file and overwrites text_B. Perhaps if you were to edit your question and give a hypothetical listing of your source and target folders (with timestamps and file sizes) both before and after, then your requirement would be clear. – dbenham Apr 26 '12 at 23:20
Sorry copying the file larger than 1kb. I want to copy the newest file from one directory to over write existing file that resides in another directory. Not copying multiple files just the newest one that exist. Hope that clarifies it. – JayC1980 Apr 27 '12 at 00:15
I'm confused, because that is what both my solutions do. They sort the files by modified date descending, then copy the 1st one that is > 1kb, overwriting the file in the destination folder. Once the newest file has been copied, they exit the loop, so only one file is copied. – dbenham Apr 27 '12 at 00:21

score 0 · Answer 2 · edited Nov 22 '17 at 01:17

@Echo OFF
Setlocal enabledelayedexpansion

:: By Elektro H@cker
::
:: Copy the Newest file in a folder greater than X bytes to a destination directory.
:: You maybe want to modify these variables:
::
Set "Source=%CD%"
Set "Destination=C:\Test\"
Set "Size=1024"
:: :: :: :: :: :: :: :: ::

for /F "tokens=1-4 delims=;" %%a in ('forfiles /P "%SOURCE%" /C "cmd /c echo @fdate;@ftime;@fsize;@path"') do (
    If %%c GTR %SIZE% (
        Set DAY=%%a
        Set DAY=!DAY:/=!
        Set HOUR=%%b
        Set HOUR=!HOUR::=!
        Echo !DAY!!HOUR!;%%d >> "%TEMP%\NewestFile.txt"
    )
)

for /F "tokens=2 delims=;" %%# in ('Type "%TEMP%\NewestFile.txt" ^| Sort /R') do (
    Copy /Y %%# "%Destination%" 1>NUL
    Del /Q "%TEMP%\NewestFile.txt"
    Exit
)

Batch Script Copying Files

2 Answers2