setof/3 and NAF

Question

so I have a set of facts:

course(cs61,  "intro to cs")
...
course(cs62b, "data structure")
...
grade(adam,       cs61, spring11, "A")
...
grade(chrisitian, cs61, fall2010, "A-")

I need to define a predicate good_standing(Student) to determine whether the Student got A in every class he took. I must use 2 different approaches:

use setof/3
use NAF

on the 1st. I have tried to figure out get Result_list: the set of students that got A from every class he took. and then call member(Student, Result_list). But I don't know what to get the Result_list since the syntax is a bit strange to me.

so, the canonical comment, [what have you tried](http://mattgemmell.com/2008/12/08/what-have-you-tried/) so far? — m09, Apr 23 '12 at 19:50

Alexander Serebrenik · Accepted Answer · 2012-04-23T20:55:14.153

1

1) For the NAF solution you should keep in mind that the good-standing student is the one with no grades lower than A, i.e., the one such that there is no course he/she took and the grade is lower than A. We also require this person to take at least one course.

good_standing(Student) :- grade(Student, _,_,_), 
                          \+ (grade(Student, Course, _, Grade), 
                              lower(Grade,"A")).

with lower/2 defining relation between the grades:

lower("A-","A").
lower("B","A").
...

The solution above works if students get only one grade per course.

2) For the setof solution you can find all grades per student and check that they are A.

grade(Student, Grade) :- grade(Student, _,_,Grade).
good_standing(Student) :- setof(Grade, grade(Student,Grade), ["A"]).

Alternatively, as suggested by false we can make the existential quantification explicit within setof:

good_standing(Student) :- setof(Grade, 
                                Course^Period^grade(Student,Course,Period,Grade),
                                ["A"]).

edited Apr 23 '12 at 20:55

answered Apr 23 '12 at 20:27

Alexander Serebrenik

3,567
2
16
32

`good_standing(Student) :- setof(Grade, Course^Year^grade(Student,Course,Year,Grade), ["A"]).` – false Apr 23 '12 at 20:39
Thank you! I'm going to edit my answer to include your suggestion. – Alexander Serebrenik Apr 23 '12 at 20:52
Concerning lower "A", it might have been meant to mean not "A". Thus using a "for all" with negation `\+ ( G, \+ P )` – false Apr 23 '12 at 21:02
I thought they also might have A+ but indeed, the suggestion to use setof might indicate that A is the highest grade. – Alexander Serebrenik Apr 24 '12 at 11:39

setof/3 and NAF

1 Answers1