What's the best way to clear regex matching variables?

Question

What's the best way to clear/reset all regex matching variables?

• Example how $1 isn't reset between regex operations and uses the most recent match:

  $_="this is the man that made the new year rumble"; 
  / (is) /; 
  / (isnt) /; 
  say $1;          # outputs "is"
  

• Example how this may be problematic when working with loops:

  foreach (...){
     /($some_value)/;
     &doSomething($1) if $1;
  }
  

---

Update: I didn't think I'd need to do this, but Example-2 is only an example. This question is about resetting matching variables, not the best way to implement them.

Regardless, originally my coding style was more inline with being explicit and using if-blocks. After coming back to this (Example2) now, it is much more concise in reading many lines of code, I'd find this syntax faster to comprehend.

Answer 1

You should use the return from the match, not the state of the group vars.

foreach (...) {
    doSomething($1) if /($some_value)/;
}

$1, etc. are only guaranteed to reflect the most recent match if the match succeeds. You shouldn't be looking at them other than right after a successful match.

Answer 2

Regex captures* are reset by a successful match. To reset regex captures, one would use a trivial match operation that's guaranteed to match.

"a" =~ /a/;  # Reset captures to undef.

Yeah, it looks weird, but you asked to do some thing weird.

If you fix your code, you don't need weird-looking workarounds. Fixing your code even reveals a bug!

Fixes:

$_ = "this is the man that made the new year rumble"; 
if (/ (is) / || / (isnt) /) {
   say $1; 
} else{ 
   ...  # You're currently printing something random.
}

and

for (...) {
   if (/($some_pattern)/) {
      do_something($1);
   }
}

---

* — Backrefs are regex patterns that match previously captured text. e.g. \1, \k<foo>. You're actually talking about "regex capture buffers".

Answer 3

You should test whether the match succeeded. For example:

foreach (...){
   /($some_value)/ or next;
   doSomething($1) if $1;
}

foreach (...){
   doSomething($1) if /($some_value)/ and $1;
}

foreach (...){
   if (/($some_value)/) {
      doSomething($1) if $1;
   }
}

Depending on what $some_value is, and how you want to handle matching the empty string and/or 0, you may or may not need to test $1 at all.

Answer 4

To complement the existing, helpful answers (and the sensible recommendation to normally test the result of a matching operation in a Boolean context and take action only if the test succeeds notwithstanding):

Depending on your scenario, you can approach the problem differently:

^{Disclaimer: I'm not an experienced Perl programmer; do let me know if there are problems with this approach.}

Enclose the matching operation in a do { ... } block scopes all regex-related special variables ($&, $1, ...) to that block.

Thus, you can use a do { ... } to prevent these special variables from getting set in the first place (although the ones from a previous regex operation outside the block will obviously remain in effect); for instance:

$_="this is the man that made the new year rumble"; 

# Match in current scope; -> $&, $1, ... *are* set.
/ (is) /;

# Match inside a `do` block; the *new* $&, $1, ... values
# are set only *inside* the block; 
# `&& $1` passes out the block's version of `$1`.
$do1 = do { / (made) / && $1 };

print "\$1 == '$1'; \$do1 == '$do1'\n";  # -> $1 == 'is'; $do1 == 'made'

• The advantage of this approach is that none of the current scope's special regex variables are set or altered; the accepted answer, by contrast, alters variables such as $&, and $'.
• The disadvantage is that you must explicitly pass out variables of interest; you do get the result of the matching operation by default, however, and if you're only interested in the contents of capture buffers, that will suffice.

Answer 5

You shoud do it this way:

foreach (...) { 
   someFnc($1) if /.../; 
}

But if you want to stick with your style, then check this as an idea:

$_ = "this is the man that made the new year rumble";  

$m = /(is)/   ? $1 : undef;
$m = /(isnt)/ ? $1 : undef;

print $m, "\n" if defined $m;

Answer 6

Assigning captures to a list behave closer to what it sounds like you want.

for ("match", "fail") {
    my ($fake_1) = /(m.+)/;
    doSomething($fake_1) if $fake_1;
}