In Perl can i apply 'grep' command on the data i captured using flip-flop operator directly?

Question

I need to find the 'number' of occurrences of particular words (C7STH, C7ST2C) that come in the output of a command. The command starts and ends with a 'fixed' text - START & END like below. This command is repeated many times against different nodes in the log file.

...

START
SLC ACL PARMG ST                   SDL                             SLI
 0  A1  17    C7STH-1&&-31         MSC19-0/RTLTB2-385
 1  A1  17    C7STH-65&&-95        MSC19-0/RTLTB2-1697

SLC ACL PARMG ST                   SDL                             SLI
 0  A2   0    C7ST2C-4             ETRC18-0/RTLTB2-417
 1  A2   0    C7ST2C-5             ETRC18-0/RTLTB2-449
 2  A2   0    C7ST2C-6             ETRC18-0/RTLTB2-961
...
END

....

I am using flip-flop operator (if (/^START$/ .. /^END$/)to get each command output. Now

Is there a way to do 'grep' on this data without going line by line? Like can i get all the text between 'START' and 'END' into an array and do 'grep' on this etc?
Also is it 'ok' to have multiple levels of if blocks with flip-flop operator from performance point of view?

Zaid: How so? I assume the text between 'START' and 'END' is an arbitrary number of lines. — flesk, Jan 02 '12 at 18:32

flesk · Answer 1 · 2012-01-02T15:09:47.010

4

This would be a simple solution:

my $number = grep {/particular word/} grep {/START/../END/} <>;

(Since you don't provide a code sample I've used the diamond operator and assumed the log file is passed as an argument to the script. Replace with file handle if needed.)

grep {/START/../END/} <> creates a list of elements within and including the delimiters, and grep {/particular word/} works on that list.

From a performance point of view you'd be better off with

for (<>) {
    $number++ if /START/../END/ and /a/;
}

Note that you have to use and instead of && or wrap your flip-flop expression in parentheses because of operator precedence.

Combining both:

my $number = grep {/START/../END/ and /particular word/} <>;

edited Jan 02 '12 at 15:09

answered Jan 02 '12 at 13:53

flesk

7,439
4
24
33

Hi flesk, Thanks for immediate reply. Sorry for not providing the sample log/code. I want count of 'different' words in the data. Because of this reason i would be going with the approach given below by Ferguson of constructing an array and using it for 'grep' on each word.. – pkr13 Jan 02 '12 at 19:19
@pkr13: Then you should accept his answer. You're also able to edit your question to include the relevant sample log/code. – flesk Jan 02 '12 at 19:44

score 1 · Accepted Answer · answered Jan 02 '12 at 14:12

1

Maybe your looking for something along these lines:

#!/usr/bin/env perl
use strict;
use warnings;
my $word = q(stuff);
my @data;
while (<DATA>) {
    if ( /^START/../^END/ ) {
        chomp;
        push @data, $_ unless /^(?:START|END)/;
    }
    if ( /^END/ ) {
        my $str = "@data";
        print +(scalar grep {/$word/} (split / /,$str)),
            " occurances of '$word'\n";
        @data = ();     
    }
}
__DATA__
this is a line
START of my stuff
more my stuff
and still more stuff
and lastly, yet more stuff
END of my stuff
this is another line
START again
stuff stuff stuff stuff
yet more stuff
END again

...which would output:

3 occurances of 'stuff'
5 occurances of 'stuff'

answered Jan 02 '12 at 14:12

JRFerguson

7,426
2
32
36

Thanks a lot for the help and appreciate your help in giving even sample code with example. Putting the lines into an array suits my purpose as i need to search for different words on that array. But understanding some of your coding style was tough for a beginner like me :). Is there any special reason for using a pattern like (?:START|END) in regex and also 2-time conversion of array to string and then splitting?? – pkr13 Jan 02 '12 at 19:58
@pkr13 : The pattern /^(?:START|END)/ matches either START or END (alternation) if the pattern is anchored to the beginning of the line. The ?: turns off capture which would be an unnecessary overhead. Without the parenthesis the pattern would have to be written as /^START|^END/ -- less readable IMHO. The array-to-string conversion was done to allow a split. This was designed to enable counting multiple pattern matches within a line as more than just one match. – JRFerguson Jan 02 '12 at 20:28

score 0 · Answer 3 · answered Jan 02 '12 at 14:45

Like can i get all the text between 'START' and 'END' into an array and do 'grep' on this etc?

(push @ar,$_) if /START/ .. /END/;
grep {/word/ @ar};

Also is it 'ok' to have multiple levels of if blocks with flip-flop operator from performance point of view?

As long as you are not working for NASA.

In Perl can i apply 'grep' command on the data i captured using flip-flop operator directly?

3 Answers3