Class fields not shared between descendants

Question

Can I declare a field as static on every descendant class instead of sharing its value for all of them ?

This is the base class:

type
  TKpModelViewControllerEntity = class(TInterfacedObject, IKpEntity)
  protected
    class var ResourceName: string; 
    procedure Manage;  
  public
    class function Create: IKpEntity;
  end;

This is a descendant

unit Customers;

type
  TCustomers = class(TKpModelViewControllerEntity)
  end;

initialization
  TCustomers.ResourceName := 'customers/';

And another one:

unit Articles;

type
  TArticles = class(TKpModelViewControllerEntity)
  end;

initialization
  TArticles.ResourceName := 'articles/';

When I try to create a Customers screen (TCustomers.Create.Manage) its Resourcename has the "articles/" value instead of "customers/".

Is there a way to indicate for the static fields to hold separate values for every descendant class ?.

Thank you.

score 5 · Accepted Answer · answered Jul 11 '23 at 11:24

This can easily be achieved with attributes:

type
  ResourceNameAttribute = class(TCustomAttribute)
  private
    FValue: string;
  public
    constructor Create(const AValue: string);
    property Value: string read FValue;
  end;

type
  TKpModelViewControllerEntity = class(TInterfacedObject, IKpEntity)
  protected
    class function ResourceName: string;
    procedure Manage;
  public
    class function Create: IKpEntity;
  end;

class function TKpModelViewControllerEntity.ResourceName: string;
begin
  Result := '';
  var ctx := TRttiContext.Create;
  var cls := ctx.GetType(Self);
  var attr := cls.GetAttribute<ResourceNameAttribute>;
  if attr <> nil then
    Result := attr.Value;
end;

constructor ResourceNameAttribute.Create(const AValue: string);
begin
  inherited Create;
  FValue := AValue;
end;

...

type
  [ResourceName('customers/')]
  TCustomers = class(TKpModelViewControllerEntity)
  end;

type
  [ResourceName('articles/')]
  TArticles = class(TKpModelViewControllerEntity)
  end;

it works like a charm and seems very elegant. Thanks for the suggestion. — Marc Guillot, Jul 11 '23 at 14:54

score 5 · Answer 2 · answered Jul 11 '23 at 16:09

I would use a class virtual method instead of a class var, eg:

type
  TKpModelViewControllerEntity = class(TInterfacedObject, IKpEntity)
  protected
    class function ResourceName: string; virtual;
    ...
  end;

class function TKpModelViewControllerEntity.ResourceName: string;
begin
  Result := ''; // or whatever default you want...
end;

type
  TCustomers = class(TKpModelViewControllerEntity)
  protected
    class function ResourceName: string; override;
    ...
  end;

class function TCustomers.ResourceName: string;
begin
  Result := 'customers/';
end;

type
  TArticles = class(TKpModelViewControllerEntity)
  protected
    class function ResourceName: string; override;
    ...
  end;

class function TArticles.ResourceName: string;
begin
  Result := 'articles/';
end;

Thanks Remy, it would definitely work, but I find the solution with attributes very neat on the descendants side, so I've gone with it. — Marc Guillot, Jul 12 '23 at 14:12
@MarcGuillot sure, using attributes will work. Just be aware that they add more RTTI to your compiled executable. Whereas this solution doesn't use any RTTI at all. — Remy Lebeau, Jul 12 '23 at 18:55

score 1 · Answer 3 · answered Jul 11 '23 at 11:08

Class fields/methods are static fields, not stored into class instance data, so it reference the first in inheritance chain.

A good pratice should be to:

Define an interface, for example IResource, which declares a method function GetResourceName: String.
Implement that interface on TCustomers and TArticles.
Query the resource name by the above method.

Class fields not shared between descendants

3 Answers3