Variable does not change in a do loop in Fortran

Question

I wrote this simple code. I obtain Q_in and Q_fin but the value of Q remains zero. So I think that the do loop doesn't work.

  program readwrite
  implicit none
  real a(200,4),Q_in,Q_fin,Q,Q_tot,v_med
  integer i,j,nj

  character*40 nome

  write(6,*) 'nome file'
  read(5,'(a)') nome
  open(unit=16,file=nome)

  nj=180

  do i=1,nj
  read(16,*) (a(i,j),j=1,4)
  enddo

        Q_in=(a(1,1)-a(1,3))/2*a(1,2)
        Q_fin=(2-a(180,1))/2*a(180,2)

  Q=0

  do i=1,nj-1

  Q=Q+1/2*((a(i+1,2)+a(i,2))*(a(i+1,1)-a(i,1)))

  enddo

        Q_tot=Q+Q_in+Q_fin

        v_med=Q_tot/2


   write(6,*) 'velocita media', v_med
     write(6,*) 'Q', Q
   write(6,*) 'Q_in', Q_in
   write(6,*) 'Q_fin', Q_fin
        end

What is in the input file? (try also with a bit smaller file, just set `nj` in your program to e.g. 5 and try to print intermediate results during debugging. — albert, Oct 12 '18 at 10:53
Put a print statement just after the read to see if a was assigned correctly — Rodrigo Rodrigues, Oct 12 '18 at 12:54
`1/2` returns 0 for integer arithmetics, this might be the cause of your problem. — Pierre de Buyl, Oct 12 '18 at 12:57
Paolo, let me know if the 1/2 problem resolved your issue, if so I can post an answer. — Pierre de Buyl, Oct 12 '18 at 13:14

score 2 · Accepted Answer · edited Oct 12 '18 at 14:27

Your error is in:

Q=Q+1/2*((a(i+1,2)+a(i,2))*(a(i+1,1)-a(i,1)))

The 1/2 is integer arithmetic and returns 0, then you multiply by the rest, still summing 0 for all iterations. Just change it to a real value 0.5

Q=Q+0.5*((a(i+1,2)+a(i,2))*(a(i+1,1)-a(i,1)))

Also, you could use array operations instead of the explicit do. Maybe this gives the compiler more chance to optimize (run and compare both approaches). You'd remove the whole do I=1, nj-1 (...) end do block and substitute by this:

Q = 0.5 * sum((a(2:nj, 2) + a(:nj-1, 2)) * (a(2:nj, 1) - a(:nj-1, 1)))

There is probably a better version with dot_product, but I'll let this as an exercise.

thank you so much. today it's my first time with fortran. i know quite good matlab infact i wrote this code like i was using matlab — Paolo Enrico Paterna, Oct 12 '18 at 14:09

Variable does not change in a do loop in Fortran

1 Answers1