6

I am using RAD XE7. In my Delphi application I want to set default values for fields of Records.

I tried following code, but it does not compile, I know it is wrong. I there any another way?

 TDtcData = record
    TableFormat     : TExtTableFormat = fmNoExtendedData;
    DTC             : integer = 0;
    Description     : string = 'Dummy';
    Status          : TDtcStatus;    
    OccurenceCnt    : integer =20;
    FirstDTCSnapShot: integer;
    LastDTCSnapShot: integer;
  end;
nil
  • 1,320
  • 1
  • 10
  • 21
Ankush
  • 89
  • 1
  • 1
  • 8
  • You could use a function in that record, returning a new record with your desired values. Look at e.g. TStopWatch record's StartNew function in System.Diagnostics. – nil Oct 16 '17 at 06:31
  • Why do you want to use records, as opposed to classes? If you are using pointers to records this sets alarm bells for me, because class objects are intrinsically pointers, and it seems to me that by using classes your problems go away. – Dsm Oct 16 '17 at 07:55
  • Actually I am migrating code to xe7 and Old code is in Codegare 2007 that why and there lot of records in old code. Creating constructor is good solution? – Ankush Oct 16 '17 at 08:03
  • If you are migrating, without seeing your code it is difficult (impossible?) to say what is the best way to go. A big difference between class objects and records is that records are created automatically and class objects have to be created explicitly. How much difficulty that difference represents to you, only you can answer, but the syntactic difference between the two is very small. – Dsm Oct 16 '17 at 08:24
  • Why not use Default()? (Delphi 10.4 and up) https://stackoverflow.com/questions/38393309/delphi-default-keyword-with-record-types-in-older-delphi-versions – Gabriel Jun 13 '22 at 08:34

2 Answers2

10

If you want to define a partially initialized record, just declare a constant record, but omit those parameters not needing default values:

Type
  TDtcData = record
  TableFormat     : TExtTableFormat;
  DTC             : integer;
  Description     : string;
  Status          : TDtcStatus;
  OccurenceCnt    : integer;
  FirstDTCSnapShot: integer;
  LastDTCSnapShot: integer;
end;

Const
  cDefaultDtcData : TDtcData = 
    (TableFormat : fmNoExtendedData; 
     DTC : 0; 
     Description : 'Dummy'; 
     OccurenceCnt : 20);

var
  someDtcData : TDtcData;
begin
  ...
  someDtcData := cDefaultDtcData;
  ...
end;
LU RD
  • 34,438
  • 5
  • 88
  • 296
  • Yes it works. but I created pointer of record like this PTDtcData = ^TDtcData; cause I want to make list of record using Tlist , so this is not works for this case ,any other way using pointer of record something like this – Ankush Oct 16 '17 at 07:33
  • 2
    A pointer works similarly: `var myP: PDtcData; begin New(myP); myP^ := cDefaultDtcData; etc...`, where `type PDtcData = ^TDtcData; TDtcData = record ... etc.` – Rudy Velthuis Oct 16 '17 at 08:15
  • 1
    With XE7 you can use generic `TList` instead of pointer approach – MBo Oct 16 '17 at 08:19
  • 3
    @Ankush, that extra specification is irrelevant to the question. Nothing stops you from making a list with pointers to one or many default records. – LU RD Oct 16 '17 at 08:42
  • Why not use Default()? https://stackoverflow.com/questions/38393309/delphi-default-keyword-with-record-types-in-older-delphi-versions – Gabriel Jun 13 '22 at 08:34
  • 1
    @ServerOverflow, the question was about how to initialize some fields in a record with specific values. `Default()` will set all fields to zero or nil. – LU RD Jun 13 '22 at 10:46
5

With the addition of 'class like' record types in Delphi, you could solve this by using a class function.

Define class function CreateNew: TDtcData; static; for your record.

The implementation sets the default values for the resulting record:

class function TDtcData.CreateNew: TDtcData;
begin
 Result.TableFormat := fmNoExtendedData;
 Result.DTC := 0;
 Result.Description :=  'Dummy';
 Result.OccurenceCnt := 20;
end;

Using this to get a record with the default values like this:

var
  AData: TDtcData;
begin
  AData := TDtcData.CreateNew;;
end.
nil
  • 1,320
  • 1
  • 10
  • 21
  • Ok this is fine for default value but I want to make list of record using Tlist and after this retrieve records from tlist – Ankush Oct 16 '17 at 08:15
  • @Ankush Your comment looks like you are accepting the answer to your question. This is a Q&A site, so if this is so, accept the answer and ask another question for your second problem. – Dsm Oct 16 '17 at 08:20
  • Why use a class method and not put the code in the Initialize "constructor"? (Delphi 10.4 and up) – Gabriel Jun 13 '22 at 08:33