Elixir/Phoenix enum through tuple to replace paths

Question

I'm parsing some HTML with Floki. And receive the following tuple:

{"html", [{"lang", "en"}],
 [{"head", [],
   [{"title", [], ["My App"]},
    {"link", [{"rel", "stylesheet"}, {"href", "/css/app.css"}], []}]},
  {"body", [],
   [{"main", [{"id", "main_container"}, {"role", "main"}], []},
    {"script", [{"src", "/js/app.js"}], [""]},
    {"iframe",
     [{"src", "/phoenix/live_reload/frame"}, {"style", "display: none;"}],
     []}]}]}

Is it possible to enumerate through all the elements, and for those that have href or src add full path to them? For example in this case replace them with: http://localhost/css/app.css and http://localhost/js/app.js

Gazler · Accepted Answer · 2017-09-01T12:37:49.970

2

Here's one way you could do it using a recursive function.

defmodule HTML do

  def use_full_path({el, attrs, children}) do
    {el, update_attrs(attrs), Enum.map(children, &use_full_path/1)}
  end

  def use_full_path(string) do
    string
  end


  defp update_attrs(attrs) do
    Enum.map(attrs, fn {key, val} ->
      if key in ["href", "src"] do
        {key, "http://localhost" <> val}
      else
        {key, val}
      end
    end)
  end
end

tree = {"html", [{"lang", "en"}],
 [{"head", [],
   [{"title", [], ["My App"]},
    {"link", [{"rel", "stylesheet"}, {"href", "/css/app.css"}], []}]},
  {"body", [],
   [{"main", [{"id", "main_container"}, {"role", "main"}], []},
    {"script", [{"src", "/js/app.js"}], [""]},
    {"iframe",
     [{"src", "/phoenix/live_reload/frame"}, {"style", "display: none;"}],
     []}]}]}

HTML.use_full_path(tree) |> IO.inspect

edited Sep 01 '17 at 12:37

answered Sep 01 '17 at 12:13

Gazler

83,029
18
279
245

`if` looks nasty in Elixir code, would you mind to change it to 2 different function clauses? – Aleksei Matiushkin Sep 01 '17 at 12:17
3

There's no need of the first `use_full_path` clause as far as I can see. – Dogbert Sep 01 '17 at 12:20
Hey @Gazler, thank you so much! Works exactly like I needed it. Have a great day! – Ilya Sep 01 '17 at 12:23

Elixir/Phoenix enum through tuple to replace paths

1 Answers1