kdb/q update multiple different values in one column for different key in keyed table

Question

I have a table, which is :

t:([alpha:`a`b`c`d`e`f];beta:10 20 30 40 50 60)

I also have two variable:

chgkey:`b`c
chgvalue:2000 -1000

I want to do something like:

t:update beta:2000 from t where alpha=`b;
t:update beta:-1000 from t where alpha=`c;

My question is how to combine these two lines of code. Because I am working on a table which is far bigger than this simple example and it will take me a lot of rows of codes to do all the updates, which is too long.

It would be nice something like

t[chgkey]`beta:chgvalue;

score 3 · Answer 1 · answered Sep 02 '16 at 15:51

3

It would be nice something like t[chgkey]`beta:chgvalue

A working solution is only slightly more complicated:

t[([]alpha:chgkey);`beta]:chgvalue

answered Sep 02 '16 at 15:51

Alexander Belopolsky

2,228
10
26

Anton Dovzhenko · Answer 2 · 2016-09-02T01:10:33.630

2

I would try to use the next query. But note that it may be slow in case if your dict is really huge

dict: `b`c ! 1000 2000;
t: update beta: ?[alpha in key dict; dict alpha;beta] from t;

In case if table t is global it can be updated with functional update:

{![`t;enlist (=;`alpha;enlist x);0b; enlist[`beta]!enlist y];}'[`b`c; 1000 2000]

edited Sep 02 '16 at 01:10

answered Sep 02 '16 at 01:01

Anton Dovzhenko

2,399
11
16

Yes, dictionary solution is nice. Can also just use fill rather than checking the keys: update beta:beta^dict alpha from t – terrylynch Sep 02 '16 at 08:44
Thanks a lot terrylynch and Dovzhenko, it's really helpful. – sxzhangzsx Sep 02 '16 at 12:51

kdb/q update multiple different values in one column for different key in keyed table

2 Answers2