sas create variable with do loop

Question

I have the following code :

data DEFBIS.Taux_fec_2006_2010;
set DEFBIS.Taux_fec_2006_2010;
  Taux_15 = 1000 * N_15 / (5 * P_15);
  Taux_16 = 1000 * N_16 / (5 * P_16);
  ...
  Taux_49 = 1000 * N_49 / (5 * P_49);
run;

How can I condense this code using a do statement from i = 15 to 49?

score 2 · Accepted Answer · edited Sep 30 '14 at 20:08

2

Two paths you can go by....

1.Macro

%macro do_loop;

data DEFBIS.Taux_fec_2006_2010;
set DEFBIS.Taux_fec_2006_2010;

%do i = 15 %to 49;
  Taux_&i. = 1000 * N_&i. / (5 * P_&i.);
%end;

run;

%mend do_loop;

%do_loop;

2.arrays

data DEFBIS.Taux_fec_2006_2010;
set DEFBIS.Taux_fec_2006_2010;

array taux (*) taux_1 -- taux_49;
array N (*) N_1 -- N_49;
array P (*) P_1 -- P_49;

do I = 15 to 49;
  Taux (I)= 1000 * N (I)/ (5 * P (I));
end;

run;

edited Sep 30 '14 at 20:08

SRSwift

1,700
9
11

answered Sep 30 '14 at 16:02

Chris

36
1

Your arrays need to go from 15--49, not 1--49. The code will work, but you'll end up with unwanted variables 1--14 – Longfish Sep 30 '14 at 16:16
Thanks all. I had tried the do loop method unsuccessfully - I'd just missed the . after &i. – user2568648 Sep 30 '14 at 16:21
The array approach is far more appropriate than the macro approach in this instance. – Robert Penridge Oct 01 '14 at 17:39

score 1 · Answer 2 · answered Sep 30 '14 at 21:03

I would not use macro's. Use an array but set the index's to be from 15 to 49 explicitly.

data DEFBIS.Taux_fec_2006_2010;
set DEFBIS.Taux_fec_2006_2010;

array taux(15:49) taux_15-taux_49;
array nn(15:49) n_15-n_49;
array pp(15:49) p_15-p_49;

do i=15 to 49;
  Taux(i) = 1000 * nn(i)/ (5 * pp(i));
end;

run;

sas create variable with do loop

2 Answers2