Number equality test fails in CLIPS pattern matching?

Question

I have this following rule in my CLIPS file:

(defrule check-final (declare (salience 12))
    ?scnt <- (set-count (value ?v) (class ?c))
    (test (= ?v ?*total*))
    =>
    (printout T ?*total* " == " ?v crlf)
)

And I get the following strange output:

CLIPS>(run)
14 == 9
5 == 2

How is this possible ????

Ernest Friedman-Hill · Accepted Answer · 2013-04-08T15:18:44.707

2

Pattern matching for this rule occurs whenever the fact set-count is asserted or modified. The rule is fired some time afterwards, during the call to run. These two processes can be widely separated in time. The value of ?*v* can of course change during that long period of time.

The key is to realize that he printed results will reflect the value of ?v from the the epoch during which pattern matching happened, while ?*total* will be the value when the results are printed. Since ?*total* may have seen arbitrary changes since the pattern matching, there's no guarantee that it will be equal to ?v when the rule actually fires.

edited Apr 08 '13 at 15:18

answered Apr 06 '13 at 12:48

Ernest Friedman-Hill

80,601
10
150
186

Thanks, that explains it. I fixed it eventually be losing the global and replacing it with a fact. Thank you again for the great answer. – Alexandru Chirila Apr 07 '13 at 08:50
I just noticed that you suggested an edit for my answer, but it got rejected before I had a chance to accept it. Your edit was completely right, for what it's worth, and I've applied it here. – Ernest Friedman-Hill Apr 08 '13 at 15:20

Alexandru Chirila · Answer 2 · 2013-04-06T10:23:10.373

0

Found part of the problem: I'm using the global ?*total* and according to the CLIPS Manual

Global variables can be accessed as part of the pattern‑matching process, but changing them does not invoke the pattern‑matching process.

But this does not explain the equality test failure

edited Apr 06 '13 at 10:23

answered Apr 05 '13 at 20:14

Alexandru Chirila

2,274
5
29
40

score 0 · Answer 3 · answered May 01 '13 at 19:06

The most likely explanation is that at some point the equality test is being satisfied and then the value of the global is changed before the rule executes.

CLIPS> (deftemplate set-count (slot value) (slot class))
CLIPS> 
(defglobal ?*total* = 0)
CLIPS> 
(defrule check-final (declare (salience 12))
    ?scnt <- (set-count (value ?v) (class ?c))
    (test (= ?v ?*total*))
    =>
    (printout T ?*total* " == " ?v crlf)
)
CLIPS> (bind ?*total* 9)
9
CLIPS> (assert (set-count (value 9) (class a)))
<Fact-1>
CLIPS> (bind ?*total* 14)
14
CLIPS> (run)
14 == 9
CLIPS> (bind ?*total* 2)
2
CLIPS> (assert (set-count (value 2) (class b)))
<Fact-2>
CLIPS> (bind ?*total* 5)
5
CLIPS> (run)
5 == 2
CLIPS>

Number equality test fails in CLIPS pattern matching?

3 Answers3

Linked