awk to translate config file to json

Question

I have a config file like this one:

[sectionOne]
key1_1=value1_1
key1_n=value1_n


#this is a comment
[sectionTwo]
key2_1=value2_1
key2_n=value2_n

;this is a comment also
[SectionThree]
key3_1=value3_1
key3_n=value3_n
[SectionFor]
...

I need to translate this into json, using minimal shell tools (no perl,python,php, just sed,awk available)

The desired output is :

[
{"sectionOne": { "key1_1": "value1_1","key1_n": "value1_n"} },
{"sectionTwo": { "key2_1": "value2_1","key2_n": "value2_n"} },
{"sectionThree": { "key3_1": "value3_1","key3_n": "value3_n"}}
....
]

I tried several ways/hours, no success

Thank you in advance

"I need to translate this into json, using minimal shell tools (no perl,python,php, just sed,awk available)" — why‽ If you've wasted several hours on this already perhaps it's time to look at the right tool for the job! — johnsyweb, Oct 31 '12 at 19:25
I looked at this for a few minutes, then noticed that you haven't written any code that you want help with, you're just asking for a hand-out. Trick-or-treat! What's the trick? — ghoti, Nov 01 '12 at 00:48

score 1 · Answer 1 · answered Oct 31 '12 at 19:14

There's some inconsistencies between your sample input and desired output so it's hard to be sure but this should be close and easy to tweak if not 100% what you want:

$ cat file
[sectionOne]
key1_1=value1_1
key1_n=value1_n


#this is a comment
[sectionTwo]
key2_1=value2_1
key2_n=value2_n

;this is a comment also
[SectionThree]
key3_1=value3_1
key3_n=value3_n
$
$ cat tst.awk
BEGIN{
   FS="="
   print "["
}

/^([#;]|[[:space:]]*$)/ {
   next
}

gsub(/[][]/,"") {
   printf "%s{\"%s\": { ", rs, $0
   rs="} },\n"
   fs=""
   next
}

{
   printf "%s\"%s\": \"%s\"", fs, $1, $2
   fs=","
}

END{
   print rs "]"
}
$
$ awk -f tst.awk file
[
{"sectionOne": { "key1_1": "value1_1","key1_n": "value1_n"} },
{"sectionTwo": { "key2_1": "value2_1","key2_n": "value2_n"} },
{"SectionThree": { "key3_1": "value3_1","key3_n": "value3_n"} },
]

score 1 · Answer 2 · answered Oct 31 '12 at 19:14

1

awk 'BEGIN{ print "[" }
    /^[#;]/{ next }  # Ignore comments
    /^\[/{ gsub( "[][]", "" ); printf "%s{\"%s\": { ", s ? "}},\n" : "", $0; n=0; s=1 }
    /=/ { gsub( "=", "\":\"" ); printf "%c\"%s\" ", n ? "," : "", $0; n=1 }
    END{ print "}}\n]" }
'

answered Oct 31 '12 at 19:14

William Pursell

204,365
48
270
300

score 0 · Answer 3 · answered Oct 31 '12 at 19:21

Here's a solution in bash using awk:

#!/bin/bash

awk -F"=" 'BEGIN{in_section=0; first_field=0; printf "["}
            {
                last=length($1);
                if ( (substr($1,1,1) == "[") && (substr($1,last, last) == "]")) {
                    if (in_section==1) {
                        printf "} },";
                    }
                    section=substr($1, 2, last-2);
                    printf "\n{\"%s\":", section;
                    printf " {";
                    first_field=1;
                    in_section=1;
                } else if ( substr($1, 1, 1) == "#" || substr($1, 1, 1) == ";"){

                } else if ( ($1 != "") && ($2 != "") ) {
                    if (first_field==0) {
                        printf ", ";
                    }
                    printf "\"%s\": \"%s\"", $1, $2;
                    first_field=0;
                }

            }
            END{printf "} }\n]\n"}'

awk to translate config file to json

3 Answers3