Coldfusion limit to total number of threads

Question

I've got some code that is trying to create 100 threaded http calls. It seems to be getting capped at about 40.

When I do threadJoin I'm only getting 38 - 40 sets of results from my http calls, despite the loop being from 1 - 100.

// thread http calls
pages = 100;

for (page="1";page <= pages; page++) {

    thread name="req#page#" {

        grabber.setURL('http://site.com/search.htm');
        // request headers
        grabber.addParam(type="url",name="page",value="#page#");
        results = grabber.send().getPrefix();

        arrayAppend(VARIABLES.arrResults,results.fileContent);
    }
}

// rejoin threads
for (page="2";page <= pages; page++) {
    threadJoin('req#page#',10000);
}

Is there a limit to the number of threads that CF can create? Is it to do with Java running in the background? Or can it not handle that many http requests?

Is there a just a much better way for me to do this than threaded HTTP calls?

nosilleg · Accepted Answer · 2012-09-17T15:06:52.927

The result you're seeing is likely because your variables aren't thread safe.

grabber.addParam(type="url",name="page",value="#page#");

That line is accessing Variables.Page which is shared by all of the spawned threads. Because threads start at different times, the value of page is often different from the value you think it is. This will lead to multiple threads having the same value for page.

Instead, if you pass page as an attribute to the thread, then each thread will have its own version of the variable, and you will end up with 100 unique values. (1-100).

Additionally you're writing to a shared variable as well.

arrayAppend(VARIABLES.arrResults,results.fileContent);

ArrayAppend is not thread safe and you will be overwriting versions of VARIABLES.arrResults with other versions of itself, instead of appending each bit.

You want to set the result to a thread variable, and then access that once the joins are complete.

thread name="req#page#" page=Variables.page {

    grabber.setURL('http://site.com/search.htm');
    // request headers
    grabber.addParam(type="url",name="page",value="#Attributes.page#");
    results = grabber.send().getPrefix();

    thread.Result = results.fileContent;
}

And the join:

// rejoin threads
for (page="2";page <= pages; page++) {
    threadJoin('req#page#',10000);
    arrayAppend(VARIABLES.arrResults, CFThread['req#page#'].Result);
}

The scope seems to be the problem. I've also scoped the **grabber** and **results** vars to **thread.grabber** and **thread.results**, I was getting repeated results until I did that as well. — Pete, Sep 17 '12 at 15:37

score 3 · Answer 2 · answered Sep 17 '12 at 13:47

In the ColdFusion administrator, there's a setting for how many will run concurrently, mine's defaulted to 10. The rest apparently are queued. An Phantom42 mentions, you can up the number of running CF threads, however, with 100 or more threads, you may run into other problems.

On 32-bit processes, your whole process can only use 2gig of memory. Each thread uses up an amount of Stack memory, which isn't part of the heap. We've had problems with running out of memory with high numbers of threads as your Java Binary+Heap+Non-Heap(PermGen)+(threads*512k) can easily go over the 2-gig limit.

You'd also have to allow enough threads to handle your code above, as well as other requests coming into your app, which may bog down the app as a whole.

I would suggest changing your code to create N threads, each of which does more than 1 request. It's more work, but you break the N requests=N Threads problem. There's a couple of approaches you can take:

If you think that each request is going to take roughly the same time, then you can split up the work and give each thread a portion to work on before you start each one up.
Or each thread picks a URL off a list and processes it, you can then join to all N threads. You'd need to make sure you put locking around whatever counter you used to track progress though.

score 0 · Answer 3 · answered Sep 17 '12 at 13:31

0

Check your Maximum number of running JRun threads setting in ColdFusion Administrator under the Request Tuning tab. The default is 50.

answered Sep 17 '12 at 13:31

Joe C

3,506
2
21
32

It was set to 50, but I'm assuming it'd be bad to just keep pushing that up. Surely any additional threads just get queued, "Maximum number of queued JRun Threads" is set to 1000 – Pete Sep 17 '12 at 13:42

Coldfusion limit to total number of threads

3 Answers3