Getting results from dispatchEvent in Flex 3

Question

I have the following custom event:

package com.un.photoManager.events
{
import flash.events.Event;

import mx.collections.ArrayCollection;


public class CreateAlbumFolderEvent extends Event
{
    // when creating an album, we need to know which albumfolder to put it in, 0 is the default group;
    public var albumFolderID:int = 0;
    public var name:String;

    public function CreateAlbumFolderEvent(type:String, name:String, albumFolderID:int = 0, cancelable:Boolean = false)
    {
        super(type, true, cancelable);
        this.name = name;
        this.albumFolderID = albumFolderID;

    }

}
}

The event gets called from a popup using the following code:

protected function handleCreate():void
        {
            var event:CreateAlbumFolderEvent;
            var selectedItemType:String;

            if (folderAlbum == CREATE_ALBUM)
            {
                event = new CreateAlbumFolderEvent(EventConstants.CREATE_ALBUM, newAlbumFolder.text, selectedAlbumFolderID);
                selectedItemType = "Album";
            }
            else
            {
                event = new CreateAlbumFolderEvent(EventConstants.CREATE_ALBUM_FOLDER, newAlbumFolder.text);
                selectedItemType = "Folder";
            }
            dispatchEvent(event);
            FolderBrowse.lastSelectedItemType = selectedItemType;
            PopUpManager.removePopUp(this);
        }

What I am trying to do is to capture the response that is handed back. Here is a screenshot of Charles showing the response. The Result value is what I am looking to be able to use once the dispatchEvent(event); has executed.

Screenshot from Charles

I have been working on this for several hours looking at blog & forum posts and have not been able to get a solution to work. Ideally, code samples would be nice, but right now any help would be appreciated.

Answer 1

er

The more important question might be how are you listening to the event? since you are dispatching the event from a popup I am going to assume you are attempting to reach this event outside of the scope of the popup.

It is important to consider the following:

In general, events work much as you would expect, with one variation: events from pop-ups don’t travel down the inheritance chain to the main application root.

Instead, events dispatched from pop-up windows are terminated at the window root. This is because the pop-up manager is the parent of the pop-up window.

As a result, events launched in the pop-up don’t bubble up to the main application page, which is the eventual parent of any object in the main application.

Popups within a Flex application are not children of the application container, but are instead children of the SystemManger.

This meaning if you simply dispatch an event it will ONLY EVER REACH the system manager and anything attempting to listen lower in the Application hierarchy (ie: everything) will not receive this.

There are many solutions to this problem and change depending on your architecture (preferred framewords (parsley, robotlegs)) but for now if you simply add a listener to Application.application.systemManager you should receive the event:

Application.application.systemManager.addEventListener(EventConstants.CREATE_ALBUM_FOLDER, [YOUR HANDLER]);

you might also need to BUBBLE the event when dispatching it.

However this is not an ideal solution to dealing with events from popups, you may want to consider injecting models into your popups and letting them publish the messages.

Hope that helps

Answer 2

You are required to override the Event.clone() method in your subclass. The clone() method returns a cloned copy of the event object by setting the type property and any new properties in the clone. Typically, you define the clone() method to return an event instance created with the new operator.

package sample
{
    import flash.events.Event;
    import mx.collections.ArrayCollection;

    public class CustomEvent extends Event
    {

        public static var DATA_LOADED:String = "dataLoaded";

        private var _data:ArrayCollection;

        public function CustomEvent(type:String, bubbles:Boolean=false, cancelable:Boolean=false, data:ArrayCollection=null)
        {
            super(type, bubbles, cancelable);
            _data = data;
        }

        override public function clone():Event
        {
            return new CustomEvent(type, bubbles, cancelable, data);
        }

        public function get data():ArrayCollection
        {
            return _data;
        }
    }
}