Perl map - need to map an array into a hash as arrayelement->array_index

Question

I have a array like this:

my @arr = ("Field3","Field1","Field2","Field5","Field4");

Now i use map like below , where /DOSOMETHING/ is the answer am seeking.

my %hash = map {$_ => **/DOSOMETHING/** } @arr

Now I require the hash to look like below:

Field3 => 0
Field1 => 1
Field2 => 2
Field5 => 3
Field4 => 4

Any help?

score 26 · Accepted Answer · answered Jun 02 '10 at 13:07

26

%hash = map { $arr[$_] => $_ } 0..$#arr;

print Dumper(\%hash)
$VAR1 = {
          'Field4' => 4,
          'Field2' => 2,
          'Field5' => 3,
          'Field1' => 1,
          'Field3' => 0
        };

answered Jun 02 '10 at 13:07

unbeli

29,501
5
55
57

score 19 · Answer 2 · answered Jun 02 '10 at 13:24

19

my %hash;
@hash{@arr} = 0..$#arr;

answered Jun 02 '10 at 13:24

Eugene Yarmash

142,882
41
325
378

3

It's a shame `%hash` has to be pre-declared, so we can't write something like `my @hash{@arr} = 0 .. $#arr;`... – Zaid Jun 02 '10 at 13:38
4

@Zaid There are always cute tricks such as `@$_{@arr} = 0 .. $#arr for \my %hash;`, but eugene's code has less shock value. – Greg Bacon Jun 02 '10 at 13:47
@gbacon : Agreed, one shouldn't sacrifice readability for one-line-cramming. It's just that I would've imagined that Perl could auto-vivify with array slices as well. – Zaid Jun 02 '10 at 13:53
@Zaid Your proposed syntax would be nice. You should send a patch to p5p! – Greg Bacon Jun 02 '10 at 14:06

score 2 · Answer 3 · answered Sep 22 '12 at 22:41

2

In Perl 5.12 and later you can use each on an array to iterate over its index/value pairs:

use 5.012;

my %hash;

while(my ($index, $value) = each @arr) {
    $hash{$value} = $index;
}

answered Sep 22 '12 at 22:41

Eugene Yarmash

142,882
41
325
378

score 2 · Answer 4 · edited May 23 '17 at 12:32

Here's one more way I can think of to accomplish this:

sub get_bumper {
    my $i = 0;
    sub { $i++ };
}

my $bump = get_bumper;         # $bump is a closure with its very own counter
map { $_ => $bump->(); } @arr;

As with many things that you can do in Perl: Don't do this. :) If the sequence of values you need to assign is more complex (e.g. 0, 1, 4, 9, 16... or a sequence of random numbers, or numbers read from a pipe), it's easy to adapt this approach to it, but it's generally even easier to just use unbeli's approach. The only advantage of this method is that it gives you a nice clean way to provide and consume arbitrary lazy sequences of numbers: a function that needs a caller-specified sequence of numbers can just take a coderef as a parameter, and call it repeatedly to get the numbers.

Why not just `my $i; my %hash = map { $_ => $i++ } @arr` – Eugene Yarmash Sep 23 '12 at 21:15 — Eugene Yarmash, Sep 23 '12 at 21:15
@eugeney: Yes, that's much simpler :) – j_random_hacker Sep 23 '12 at 21:19 — j_random_hacker, Sep 23 '12 at 21:19

score 1 · Answer 5 · answered Mar 15 '22 at 07:59

1

A very old question, but i had the same problem and this is my solution:

use feature ':5.10';

my @arr = ("Field3","Field1","Field2","Field5","Field4");
my %hash = map {state $i = 0; $_ => $i++} @arr;

answered Mar 15 '22 at 07:59

KlausR

27
3

Perl map - need to map an array into a hash as arrayelement->array_index

5 Answers5

Linked

Related