Gradle Script To call a REST Web service without any 3rd party plugins, any pointers?

Question

Hi I need to call a REST service as part of the buildscript (Gradle) without any 3rd party plugins, how could I use Groovy to do that?

(My first attempt)

repositories {
    mavenCentral()
}
      dependencies {  
            complie "org.codehaus.groovy.modules.http-builder:http-builder:0.5.2"  
    }  

task hello {
    def http = new HTTPBuilder("http://myserver.com:8983/solr/select?q=*&wt=json")
    http.auth.basic 'username', 'password'
    http.request(GET, JSON ) { req ->
    }
}

Answer 1

Can't you just do

new URL( 'http://username:password@myserver.com:8983/solr/select?q=*&wt=json' ).text

Answer 2

this is working guys

import java.io.*
import groovyx.net.http.HTTPBuilder
import groovyx.net.http.EncoderRegistry
import static groovyx.net.http.Method.*
import static groovyx.net.http.ContentType.*

buildscript {
    repositories {
        mavenCentral()
    }   
    dependencies {
        classpath 'org.codehaus.groovy.modules.http-builder:http-builder:0.5.2'
    }   
}

task hello {
    def http = new groovyx.net.http.HTTPBuilder("http://local.com:8983/solr/update/json")

    http.request(POST, JSON ) { req ->
        req.body{

        }
        response.success = { resp, reader ->
            println "$resp.statusLine   Respond rec"

        }
    }
}

Answer 3

This question is ranking so well on search engines that I keep stumbling on it.

However, as others commented, I don't really like the accepted answer because it relies on curl.

So here is a complete example w/o any prerequisite (no plugin, no curl, ...):

import groovy.json.JsonSlurper
import groovy.json.JsonOutput
task getExample {
    doLast {
        def req = new URL('https://jsonplaceholder.typicode.com/posts/1').openConnection()
        logger.quiet "Status code: ${req.getResponseCode()}"
        def resp = new JsonSlurper().parseText(req.getInputStream().getText())
        logger.quiet "Response: ${resp}"
    }
}
task postExample {
    doLast {
        def body = [title: "foo", body: "bar", userId: 1]
        def req = new URL('https://jsonplaceholder.typicode.com/posts').openConnection()
        req.setRequestMethod("POST")
        req.setRequestProperty("Content-Type", "application/json; charset=UTF-8")
        req.setDoOutput(true)
        req.getOutputStream().write(JsonOutput.toJson(body).getBytes("UTF-8"))
        logger.quiet "Status code: ${req.getResponseCode()}" // HTTP request done on first read
        def resp = new JsonSlurper().parseText(req.getInputStream().getText())
        logger.quiet "Response: ${resp}"
    }
}

You can run this on your box as they use a public development API.

Answer 4

The easiest way to call REST from groovy without external libraries is executing CURL. Here's an example of calling Artifactory, getting JSON back and parsing it:

import groovy.json.JsonSlurper

task hello {
    def p = ['curl', '-u', '"admin:password"', "\"http://localhost:8081/api/storage/libs-release-local?list&deep=1\""].execute()
    def json = new JsonSlurper().parseText(p.text)
}

Answer 5

I'm using the JsonSlurper it looks quite simple and OS independent:

import groovy.json.JsonSlurper

String url = "http://<SONAR_URL>/api/qualitygates/project_status?projectKey=first"
def json = new JsonSlurper().parseText(url.toURL().text)
print json['projectStatus']['status']

Answer 6

Java has had a proper HTTP Client in the standard library since Java 9.

Here's how you can use that from a Gradle script (Groovy):

import groovy.json.JsonSlurper

import java.net.http.*
import static java.nio.charset.StandardCharsets.UTF_8

tasks.register('hello') {
    def url = new URL("http://myserver.com:8983/solr/select?q=*&wt=json")
    def req = HttpRequest.newBuilder(url.toURI()).GET().build()
    def res = HttpClient.newHttpClient()
       .send(req, HttpResponse.BodyHandlers.ofString(UTF_8))
    def parsedJson = new JsonSlurper().parseText(res.body())
    println parsedJson
}

Answer 7

The solution using Kotlin DSL and Fuel HTTP Client:

import com.github.kittinunf.fuel.httpPost
import com.github.kittinunf.result.Result

buildscript {
    dependencies {
        "classpath"("com.github.kittinunf.fuel:fuel:2.3.1")
    }
}

tasks {
    register("post") {
        val (request, response, result) = "https://httpbin.org/post".httpPost().responseString()
        if (result is Result.Success) {
            println(result.get())
        }
    }
}